Copy Every Nth Row with Macro - excel

Question

I am using Excel VBA to create a macro to copy every other row starting at P7 downward. I want these copied values to be pasted normally into another workbook as a continuous column. I am pretty sure this will require a for loop, but I am not sure how to do it in VBA. Below is my current code, which just copies the filled rows without skipping.
Option Explicit
Sub copyRange()
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
Dim i As Integer
Dim wkbDest As Workbook
Dim wkbSource As Workbook
Set wkbDest = ThisWorkbook
Dim strExtension As String
Dim LastRowC As Long
Dim LastRowP As Long
Dim filterRange As Range
Dim copyRange As Range
Const strPath As String = "C:\Users\User1\Desktop\UPLOADS2\"
ChDir strPath
strExtension = Dir(strPath & "*.xls*")
Do While strExtension <> ""
Set wkbSource = Workbooks.Open(strPath & strExtension)
With wkbSource.Sheets("Sheet1")
LastRowC = wkbSource.Worksheets("Sheet1").Cells(Rows.Count, "B").End(xlUp).Row
'LastRowP = wkbDest.Worksheets("WIP").Cells(wkbDest.Worksheets("WIP").Rows.Count, "P").End(xlUp).Offset(1).Row
wkbSource.Worksheets("Sheet1").Range("B4:B" & LastRowC).Copy
wkbDest.Worksheets("WIP").Range("P7").PasteSpecial Paste:=xlPasteValuesAndNumberFormats
Application.CutCopyMode = False
End With
wkbSource.Close savechanges:=False
strExtension = Dir
Loop
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub

Answer 1

You can manage the step of a for loop to modify the number iterated via next i, such that:
Dim i as Long
For i = 4 to LastRowC Step 2
'Use Cells(i,"B") or Range("B" & i)
Next i
In this case, the step of 2 would make you go from 4 to 6 to 8, etc.

Answer 2

Just for fun, an alternative without any loop:
Dim lr As Long
With Sheet1
lr = .Cells(.Rows.Count, 2).End(xlUp).Row: If lr Mod 2 = 1 Then lr = lr - 1
.Range(Join(.Evaluate("TRANSPOSE(""B""&2+ROW(1:" & ((lr - 4) / 2) + 1 & ")*2)"), ",")).Copy
End With
Not tested, but might speed up the process since you only need to use the clipboard once.

Answer 3

Below is a complete subroutine that will select every 2nd cell in a selected range and then copy the cells to the clipboard. This will work on a range of rows in a single column. It shouldn't be too difficult to modify it to make it work in the other direction, though. If you want to copy every 3rd, 4th, etc. cell you just need to modify the Step value in the for loop.
Sub Select_Every_Other()
'
' Select_Every_Other Macro
' Select every other cell in a selected range (column)
'
Dim Rng As Range ' original selection
Dim myCell As Range ' temp variable
Dim myUnion As Range ' final selection
Set Rng = Selection
For i = 1 To Rng.Rows.Count Step 2
Set myCell = Rng.Cells(i)
If myUnion Is Nothing Then ' if myUnion is empty (first time through loop)
Set myUnion = myCell ' create a new union
Else ' if myUnion is not empty
Set myUnion = Union(myUnion, myCell) ' add to the union
End If
Next i
myUnion.Select
Selection.Copy
End Sub
This code was adapted from here: https://spreadsheetplanet.com/select-every-other-cell-in-excel/