Soundcloud song names - excel

Question

I'm new to VBA web scraping and html structure in general and I'm having some trouble getting the song names off this html address "https://soundcloud.com/maraudamusic/tracks"
This is what I have tried so far and I can't seem to pull the <li> song names from the html document (I barely know what I'm talking about so forgive me).
Option Explicit
Sub SCScrape()
Dim ie As InternetExplorer
Dim html As HTMLDocument
Dim site As String
Dim artist As String
artist = "maraudamusic"
site = "https://soundcloud.com/" & artist & "/tracks"
Set ie = New InternetExplorer
ie.Visible = True
ie.navigate site
Do While ie.readyState <> READYSTATE_COMPLETE
DoEvents
Loop
Set html = New HTMLDocument
Dim ul As IHTMLElementCollection
'Dim ul As Variant
'Dim li As IHTMLListElement
Dim els As Variant
Dim el As Variant
'Dim li As Variant
'Set ul = html.getElementsByClassName("lazyLoadingList__list sc-list-nostyle sc-clearfix")
'Set ul = html.getElementsByTagName("ul")
Set els = html.getElementsByClassName("soundTitle_usernameTitleContainer")
Debug.Print
For Each el In els
Debug.Print el.innerHTML
Next el
Debug.Print "Hello"
End Sub

Answer 1

The main issue is trying to read elements from a blank document...
You set html = New HTMLDocument. This instantiates the html object as a blank HTMLDocument object.
What you should do is set html = ie.document to read the contents of the current document in the IE window.
Also, as Soundcloud is a Javascript/AJAX type application, you may need to wait a couple of seconds for AJAX calls to finish. This may not be necessary but I find it sometimes helps.
Here's a working example.
Option Explicit
Sub SCScrape()
Dim ie As InternetExplorer
Dim html As HTMLDocument
Dim site As String
Dim artist As String
artist = "maraudamusic"
site = "https://soundcloud.com/" & artist & "/tracks"
Set ie = New InternetExplorer
ie.Visible = True
ie.navigate site
Do While ie.readyState <> READYSTATE_COMPLETE
DoEvents
Loop
Application.Wait (Now + TimeValue("0:00:03")) ' wait for ajax...
Set html = ie.Document 'get the document from IE
Dim els As Variant
Dim el As Variant
Set els = html.getElementsByClassName("soundTitle__title")
For Each el In els
Debug.Print el.innerText
Next el
Debug.Print "Hello"
End Sub