Command button press cycles through a desired range - excel

Question

I'm trying to write code to where on each command button press, the current time is put into the first cell in a range. Then on the next button click, the next cell in the range is filled with the current time, and so on. I cant figure out how to cycle through the desired range and place a time value at that cell on each button press.
I have a basic double For loop that goes through the entire range I want and populates all cells with the current time at once. I only want one cell to populate at a time with the current time on each button click, and I cant figure out how for the life of me.
code so far:
Private Sub CommandButton1_Click()
Dim i As Integer, j As Integer
For i = 6 To 115
For j = 3 To 5
Cells(i, j).Value = Time
Next j
Next i
End Sub

Answer 1

I understand it like that
Private Sub CommandButton1_Click()
Dim rg As Range
Set rg = Range("C6:E115")
Dim sngCell As Range
For Each sngCell In rg
If Len(sngCell.Value) = 0 Then
sngCell.Value = Time
Exit For
End If
Next
End Sub
Update:
This solution should be faster but I think it will not be noticeable.
Private Sub CommandButton1_Click()
Dim rg As Range
Set rg = Union(Range("C5"), Range("C6:E115"))
Dim nextCell As Range
Set nextCell = rg.Find("")
If Not nextCell Is Nothing And nextCell.Address <> "$C$5" Then
nextCell.Value = Time
End If
End Sub

Answer 2

this should do the trick:
Option Explicit
Private Sub CommandButton1_Click()
Dim i As Integer, j As Integer
Dim emptyCellFound As Boolean
Dim c As Range
emptyCellFound = False 'not really needed. just for clarity
For i = 6 To 115
For j = 3 To 5
Set c = Cells(i, j)
If c.Value = "" And Not emptyCellFound Then
c.Value = Time
emptyCellFound = True
End If
Next j
Next i
End Sub

Answer 3

This works if any value is applied in any cell below row 114
Private Sub CommandButton1_Click()
On Error Resume Next
[C6:E115].SpecialCells(xlCellTypeBlanks).Cells(1).Value = Time
On Error GoTo 0
End Sub
..without a value below row 114 this works
Private Sub CommandButton1_Click()
On Error GoTo weird
[C6:E115].SpecialCells(xlCellTypeBlanks).Cells(1).Value = Time
Exit Sub
weird:
If [C115].End(xlUp).Row > 6 Then [C115].End(xlUp).Offset(1).Value = Time
On Error GoTo 0
End Sub