grouped and alternating conditional formatting - excel

Question

I have 3 sites, each of them have worked some tickets that I am reviewing. I would like to alternate between 2 shades of one color for each group: Site 1 would alternate between a lighter and a darker green, Site 2 would alternate between two shades of red, and Site 3 the same with Blue. However, I do not want to alternate every row, but rather every other ticket. The tickets may have a variable number of rows that are grouped with it. See screenshot where i have manually applied an example of the formatting im going for (these are not the final colors, these are used because the originals werent viewable after the image was uploaded).
Here is an image with the sample formatting:
Im fairly certain a helper column will be required here and while i'm fairly decent with excel and conditional formatting this one is a bit beyond me.

Answer 1

I will only use the Site column and Ticket column from your example to demonstrate my solution. Suppose the Site column is in Column A and Ticket column is in Column B, I will use Column C as the helper column in the following way presume the first row is for headers that do not need to be formatted:
In cell C2 enter number 1, this value is hard-coded/static;
In cell C3 enter the following formula and drag it down to the end of your table:
=MOD(IF(LEN($B3)=0,$C2,IF($B3=$B2,$C2,$C2+1)),2)
Then you should have a helper column showing either 1 or 0 based on the ticket number.
Highlight your table with cell A1 (i.e. the first cell of the range excluding header) being the active cell, set up the following conditional formatting rules one by one:
| Conditional Formatting Rules: | Format |
|-------------------------------|-------------|
| =(MAX($A$2:$A2)*10+$C2)=11 | Light Green |
| =(MAX($A$2:$A2)*10+$C2)=10 | Dark Green |
| =(MAX($A$2:$A2)*10+$C2)=21 | Light Red |
| =(MAX($A$2:$A2)*10+$C2)=20 | Dard Red |
| =(MAX($A$2:$A2)*10+$C2)=31 | Light Blue |
| =(MAX($A$2:$A2)*10+$C2)=30 | Dark Blue |
Then you should have the following:
Please note Column D Rule is for demonstration only which is not necessary in the actual table. It shows you how my formulas have differentiated each row based on Site and Ticket.
EDIT #2
Given that the Site ID are actually texts rather than numbers, here is an alternative approach, which is still using the helper column as illustrated in the original solution, but the conditional formatting rules will be changed to:
| Conditional Formatting Rules: | Format |
|---------------------------------------------------------------------------------------------|-------------|
| =(INDEX($A$2:$A2,AGGREGATE(14,7,ROW($A$1:$A1)/ISTEXT($A$2:$A2),1))&"#"&$C2)="Site Name 1#1" | Light Green |
| =(INDEX($A$2:$A2,AGGREGATE(14,7,ROW($A$1:$A1)/ISTEXT($A$2:$A2),1))&"#"&$C2)="Site Name 1#0" | Dark Green |
| =(INDEX($A$2:$A2,AGGREGATE(14,7,ROW($A$1:$A1)/ISTEXT($A$2:$A2),1))&"#"&$C2)="Site Name 2#1" | Light Red |
| =(INDEX($A$2:$A2,AGGREGATE(14,7,ROW($A$1:$A1)/ISTEXT($A$2:$A2),1))&"#"&$C2)="Site Name 2#0" | Dard Red |
| =(INDEX($A$2:$A2,AGGREGATE(14,7,ROW($A$1:$A1)/ISTEXT($A$2:$A2),1))&"#"&$C2)="Site Name 3#1" | Light Blue |
| =(INDEX($A$2:$A2,AGGREGATE(14,7,ROW($A$1:$A1)/ISTEXT($A$2:$A2),1))&"#"&$C2)="Site Name 3#0" | Dark Blue |
Here is the screen-shot:
Let me know if you have any questions. Cheers :)