Passing an array between click Subs in VBA - excel

Question

I am trying to declare and populate an array variable (coll), but wish to access the contents of the array in another Sub (UnassignButton_Click()). I keep getting the error:
Compile error: Sub or Function not defined
Below is my code:
Public Sub SearchButton_Click()
Dim RowNum As Long
Dim SearchRow As Long
Dim coll As Object
Set coll = CreateObject("System.Collections.ArrayList")
RowNum = 2
SearchRow = 2
Do Until Cells(RowNum, 1).Value = ""
If InStr(1, Cells(RowNum, 1).Value, SearchTextBox.Value, vbTextCompare) > 0 Then
Worksheets("Search_Results").Cells(SearchRow, 1).Value = Cells(RowNum, 1).Value
Worksheets("Search_Results").Cells(SearchRow, 2).Value = Cells(RowNum, 2).Value
Worksheets("Search_Results").Cells(SearchRow, 3).Value = Cells(RowNum, 3).Value
Worksheets("Search_Results").Cells(SearchRow, 4).Value = Cells(RowNum, 4).Value
Worksheets("Search_Results").Cells(SearchRow, 5).Value = Cells(RowNum, 5).Value
Worksheets("Search_Results").Cells(SearchRow, 6).Value = Cells(RowNum, 6).Value
Worksheets("Search_Results").Cells(SearchRow, 7).Value = Cells(RowNum, 7).Value
Worksheets("Search_Results").Cells(SearchRow, 8).Value = Cells(RowNum, 8).Value
Worksheets("Search_Results").Cells(SearchRow, 9).Value = Cells(RowNum, 9).Value
SearchRow = SearchRow + 1
coll.Add RowNum
End If
RowNum = RowNum + 1
Loop
If SearchRow = 2 Then
MsgBox "No products were found that match your search criteria"
Exit Sub
End If
SearchResultsListBox.RowSource = "SearchResults"
End Sub
Private Sub SearchResultsListBox_Click()
NumberIndex = SearchResultsListBox.ListIndex
End Sub
Public Sub UnassignButton_Click()
NumberIndex = SearchResultsListBox.ListIndex
MsgBox coll(NumberIndex)
End Sub
Any help to resolve this issue would be much appreciated!

Answer 1

See this answer for why you can't just willy-nilly tweak event handler procedure signatures to suit your needs.
Each procedure defines a scope. Local variables (whether declared with Dim, ...or not declared at all) live inside that procedure scope, and have no way out.
The next higher-up scope level is module scope. Variables declared in that scope are accessible to all procedures in the module. Use the Private keyword to declare them (Dim is also legal, but I prefer to reserve it for locals, since Private isn't legal at procedure level) - consider using a meaningful identifier name, too... "coll" doesn't say much about what it's for:
Option Explicit
Private RowNumbers As Object
And then you can initialize it in the Initialize handler:
Private Sub UserForm_Initialize()
Set RowNumbers = CreateObject("System.Collections.ArrayList")
End Sub
Probably also a good idea to explicitly wipe it out in the Terminate handler too, since that's a .NET object (FWIW this isn't a VBA array at all and has nothing to do with arrays):
Private Sub UserForm_Terminate()
Set RowNumbers = Nothing
End Sub
The next higher-up scope level is global scope, but once you understand how to pass parameters between procedures, and when to use module scope variables, you pretty much never need any globals. For completleness' sake, a global variable would be declared in a standard module, using the Public keyword (Global works too, but makes things confusing since what we call "global" is really just "project-scope", and besides Public is much more clearly antagonizing Private, so it's good for consistency).
If you added Option Explicit to the top of your modules, VBA would refuse to compile code that uses undeclared variables - and that would have highlighted coll and, likely, NumberIndex as well.
See if Rubberduck inspections flag other issues (disclaimer: I manage that open-source project).