Excel VBA Nested Do Loop that reads ahead - excel

Question

I am trying to read all values in column G until it finds a blank cell. If values are "Permits Received" or "Cancelled" then I write "Ready to Build" in column H. If I encounter anything other than received or cancelled then I write "Missing Permits". So, I need to read ALL populated cells in column G and write ready... or missing... in column H. The problem with my code is 1) its probably not the best approach, and 2) it only reads the first cell in column G then writes the output.
This is for an automated workbook that works like a champ except for this loop. I have been goofing with For Next, Do While and For Each with varying success but the code below is the closest I've been.
Dim i As Integer, j As Integer, rng As Range
Set rng = Range("$G$2:$G$" & ActiveSheet.UsedRange.Rows.Count) ' Set range to all used rows in column G
For i = 2 To rng.Rows.Count
Do While Cells(i, 7).Value = ""
If Cells(i + 1, 7).Value = "Permits Received" Or Cells(i + 1, 7).Value = "Cancelled" Then
Cells(i, 8).Value = "Ready to Build"
Else: Cells(i, 8).Value = "Missing Permits"
End If
i = i + 1
If i = rng.Rows.Count Then Exit For ' Without this code it will read all rows, not just used rows
Loop
Next i
I expect the loop to read all column G values then decide if it is "Ready to Build" or "Missing Permits". The code runs to the 35766 then errs with Overflow if the Exit For is not included.
(new) I only need one output line (col H) per each line or group of lines (col G). The attached image shows how the output should look. Thank you so, so much for looking at this!!! I've been staring at it for a week!
Example of input and correct output, need code for column H
Example of output from latest solution

Answer 1

Solution based on the image published:
Assuming that the default value for any FIB:BUR group is "Missing Permits", unless all of its FIB:PERMITs have the values "Permits Received" or "Cancelled" then it should be marked as "Ready to Build".
This proposed solution uses AutoFilter object (Excel) combined with the Range.SpecialCells method (Excel). To create a range in which the groups are separated by Range.Areas property (Excel).
Then it uses For…Next and the WorksheetFunction.CountIf to validate the presence of "Permits Received" or "Cancelled", and Range.Offset Property (Excel) to set the resulting value for the group.
Sub Solution()
Dim rSrc As Range, rTrg As Range
Dim rArea As Range
Dim bCnt As Byte 'Change data type to long if the number of FIB:PERMITs by FIB:BUR exceeds 255
With ThisWorkbook.Worksheets("DATA") 'change as required
If Not (.AutoFilter Is Nothing) Then .Cells(1).AutoFilter
Set rSrc = .Cells(2, 7).Resize(-1 + .UsedRange.Rows.Count, 2)
End With
With rSrc
.Columns(2).ClearContents
.Offset(-1, 0).Resize(1 + .Rows.Count).AutoFilter
.AutoFilter Field:=1, Criteria1:="<>"
Set rTrg = .Columns(1).SpecialCells(xlCellTypeVisible)
.AutoFilter
End With
For Each rArea In rTrg.Areas
bCnt = 0
With WorksheetFunction
bCnt = .CountIf(rArea, "Cancelled")
bCnt = bCnt + .CountIf(rArea, "Permits Received")
rArea.Cells(1).Offset(-1, 1).Value2 = _
IIf(bCnt = rArea.Rows.Count, "Ready to Build", "Missing Permits")
End With: Next
End Sub
Answer to original question
Instead of using a Do…Loop within the For…Next, you could have used IF…ELSEIF or Select Case statement. This proposed solution uses Select Case
Sub Solution_1()
Dim rTrg As Range, lRow As Long
With ThisWorkbook.Worksheets("DATA") 'change as required
Set rTrg = .Cells(2, 7).Resize(-1 + .UsedRange.Rows.Count, 2)
End With
With rTrg
For lRow = 1 To .Rows.Count
Select Case .Cells(lRow, 1).Value2
Case vbNullString 'NO ACTION!
Case "Permits Received", "Cancelled"
.Cells(lRow, 2).Value2 = "Ready to Build"
Case Else
.Cells(lRow, 2).Value2 = "Missing Permits"
End Select: Next: End With
End Sub
However, I try to avoid For…Next whenever is possible, so this alternate solution uses
AutoFilter object (Excel) combined with the Range.SpecialCells method (Excel).
Sub Solution_2()
Dim rTrg As Range
With ThisWorkbook.Worksheets("DATA") 'change as required
If Not (.AutoFilter Is Nothing) Then .Cells(1).AutoFilter
Set rTrg = .Cells(2, 7).Resize(-1 + .UsedRange.Rows.Count, 2) ' Set range to all used rows in column G
End With
With rTrg
.Offset(-1, 0).Resize(1 + .Rows.Count).AutoFilter
.Columns(2).Value2 = "!"
.AutoFilter Field:=2, Criteria1:="!"
.AutoFilter Field:=1, Criteria1:="=Cancelled", _
Operator:=xlOr, Criteria2:="=Permits Received"
.Columns(2).SpecialCells(xlCellTypeVisible).Value2 = "Ready to Build"
.AutoFilter Field:=1, Criteria1:="<>"
.Columns(2).SpecialCells(xlCellTypeVisible).Value2 = "Missing Permits"
.AutoFilter Field:=1
.Columns(2).SpecialCells(xlCellTypeVisible).ClearContents
.Cells(1).AutoFilter
End With
End Sub

Answer 2

I've encountered a similar issue when using a for loop to iterate rows like that when I use an integer as the data type for my loop index variable. The Excel integer data is 2-bytes in length and has a range of -32,768 to 32,767. Perhaps your mention of "35766" was a typo for 32766 or 32767. If you change your variable 'i' from an int to a long, I would expect your issue to go away.
If this macro is something for your personal use rather than something others will be using, I've often used the following approach to iterate down one column and modify another cell that's on the same row:
Do While IsEmpty(ActiveCell.value) = False
If ActiveCell.value = "X" Then
ActiveCell.Offset(0, 1).value = "M" ' ActiveCell.Offset(row_offset, column_offset)
ElseIf ActiveCell.value = "Y" Then
ActiveCell.Offset(0, 1).value = "N"
End If
ActiveCell.Offset(1, 0).Activate ' From currently active cell, activate the next cell one row down
Loop
Before running a macro using this technique, you'd have to activate the first cell in the column being evaluated - which becomes the cell first evaluated as the ActiveCell.