Question about referencing specific indexes in Terraform Interpolation - terraform

Question

Let me first start out by saying that I currently have a working terraform configuration, however my IDE (VSCode; using the mauve.terraform extension, v 1.3.12) complains about my syntax when I do something like:
virtual_machine_name = "${azurerm_virtual_machine.sql["${count.index}"].name}"
It complains that it's expecting a '}' but found a '.'.
Should I be writing this out differently, or in a more "correct" manner? I'm fairly new to working with terraform so I'm sure my syntax could use some help.
Thanks in advance!
For reference, here's my full resource block:
resource "azurerm_virtual_machine_extension" "sql" {
name = "OMSExtension"
location = "${data.azurerm_resource_group.generics_sql_dev.location}"
resource_group_name = "${data.azurerm_resource_group.generics_sql_dev.name}"
virtual_machine_name = "${azurerm_virtual_machine.sql["${count.index}"].name}"
publisher = "Microsoft.EnterpriseCloud.Monitoring"
type = "MicrosoftMonitoringAgent"
type_handler_version = "1.0"
auto_upgrade_minor_version = true
count = "${var.sql_node_count}"
settings = <<-BASE_SETTINGS
{
"workspaceId" : "${data.azurerm_log_analytics_workspace.oms.workspace_id}"
}
BASE_SETTINGS
protected_settings = <<-PROTECTED_SETTINGS
{
"workspaceKey" : "${data.azurerm_log_analytics_workspace.oms.primary_shared_key}"
}
PROTECTED_SETTINGS
}

Answer 1

From Terraform 0.12 and later, the "standard" way to write that is:
virtual_machine_name = azurerm_virtual_machine.sql[count.index].name
What you tried would also work in Terraform 0.12, but the string interpolations are redundant in that version. It works in Terraform 0.12 because of a special backward-compatibility rule that if a quoted string sequence consists only of a single interpolation (like "${ ...anything ... }") then Terraform will ignore the quotes and just return the inner expression value directly.
That's only supported for backward-compatibility with configurations written for Terraform 0.11 and so I'd recommend avoiding it if you are using Terraform 0.12 or later; it tends to hurt readability by leaving a reader wondering if it implies conversion to a string.
For Terraform 0.11 and earlier, one level of string interpolation is required and indexing must be against a "splat operator":
virtual_machine_name = "${azurerm_virtual_machine.sql.*.name[count.index]}"
The azurerm_virtual_machine.sql.*.name part here produces a list of name values, and then [count.index] selects one of them. This approach is required in Terraform 0.11 and earlier because in those versions the index operator [...] must always come at the end of a sequence of traversal steps.