Developing proper algorithm for numeric combination - excel

Question

Hello to all experts in Excel formula programming and mathematicians.
I am trying to develop a formula applicable in Excel that generates possible combinations of 7 numbers within number span from 1 to 50.
Interesting here is that I can`t find a proper way how to fully integrate all needed variables in same formula for expected result.
Following variables I am trying to integrate are these:
numbers can be formed from 1 and 2 digits
number span to form combination of numbers is from 1 - 50
each combination contains 7 different numbers (without repeating inside same combination)
numbers should be lined in order from smallest to highest value if possible
to simplify (reduce) from all possible combinations, it is crucial that combinations can be generated from "manually inserted" chosen numbers (they are within this same numeric span of 1 - 50). This is what I think is most challenging how to create.
alternatively, is it possible to integrate in this kind of formula a loop that checks or blocks that same combination of set of 7 numbers are repeated within all combinations? This is to prevent repeating of same set of combination of numbers within ultimate possible of combinations following these all previous conditions.
Thank you for support,
DucyD

Answer 1

This is not a complete solution.
But it will list the first 1,000,000 combinations (the total number would be around 99,884,401):
Sub kombo()
Z = 1
For a = 1 To 50 - 6
For b = a + 1 To 50 - 5
For c = b + 1 To 50 - 4
For d = c + 1 To 50 - 3
For e = d + 1 To 50 - 2
For f = e + 1 To 50 - 1
For g = f + 1 To 50
Cells(Z, 1) = a & "," & b & "," & c & "," & d & "," & e & "," & f & "," & g
Z = Z + 1
If Z = 1000000 Then Exit Sub
Next g
Next f
Next e
Next d
Next c
Next b
Next a
End Sub
Near the top:
At the bottom:

Answer 2

User defined function that accepts a comma an array of comma delimited numbers and generates a combination is within the first five parameters described in OP. The last parameter greatly complicates the problem, do you expect to get collisions? Are you planning on generating a million sets of combinations, fifty, a hundred thousand? You can pass the range that you want to check to CombinationGenerator and check. See bottom of post for an idea as to handle this parameter.
Option Explicit
Public Function CombinationGenerator(Optional ByRef valueString As String) As String
Dim rndNum As Long
Dim indexI As Long
Dim indexII As Long
Dim doubleValuePass As Boolean
Dim tempStr As String
Dim position As Long
Dim values() As String
Dim shuffled(7) As String
values = Split(valueString, ",")
ReDim Preserve values(7)
For indexI = 0 To UBound(values)
If values(indexI) = "" Then
Randomize
rndNum = Int(Rnd * 50) + 1
values(indexI) = CStr(rndNum)
Do Until doubleValuePass = True
doubleValuePass = True
For indexII = 0 To UBound(values)
If (values(indexI) = values(indexII)) And (indexI <> indexII) Then
doubleValuePass = False
Randomize
rndNum = Int(Rnd * 50) + 1
values(indexI) = CStr(rndNum)
End If
Next indexII
Loop
doubleValuePass = False
End If
Next indexI
For indexI = 0 To UBound(values)
position = 0
For indexII = 0 To UBound(values)
If CInt(values(indexI)) > CInt(values(indexII)) Then position = position + 1
Next indexII
shuffled(position) = values(indexI)
Next indexI
For indexI = 0 To UBound(shuffled)
tempStr = tempStr + "," + shuffled(indexI)
Next indexI
tempStr = Right(tempStr, Len(tempStr) - 1)
CombinationGenerator = tempStr
End Function
This breaks the functions out. The last function, to check that your generated string does not exist in a range that you have passed to the first function, really depends on expected use.
Option Explicit
Public Function CombinationGenerator(Optional ByRef valueString As String, Optional ByRef rng As Range) As String
Dim tempStr As String
Dim position As Long
Dim inputValues() As String
Dim combination() As String
inputValues = Split(valueString, ",")
ReDim Preserve inputValues(7)
combination = CombinationGenerate(inputValues)
combination = CombinationShuffle(combination)
tempStr = CombinationToString(combination)
tempStr = CombinationNotInRange(tempStr)
CombinationGenerator = tempStr
End Function
Private Function CombinationGenerate(ByRef combination() As String) As String()
Dim indexI As Long
Dim indexII As Long
Dim rndNum As Long
Dim doubleValuePass As Boolean
For indexI = 0 To UBound(combination)
If combination(indexI) = "" Then
Randomize
rndNum = Int(Rnd * 50) + 1
combination(indexI) = CStr(rndNum)
Do Until doubleValuePass = True
doubleValuePass = True
For indexII = 0 To UBound(combination)
If (combination(indexI) = combination(indexII)) And (indexI <> indexII) Then
doubleValuePass = False
Randomize
rndNum = Int(Rnd * 50) + 1
combination(indexI) = CStr(rndNum)
End If
Next indexII
Loop
doubleValuePass = False
End If
Next indexI
CombinationGenerate = combination
End Function
Private Function CombinationShuffle(ByRef combination() As String) As String()
Dim indexI As Long
Dim indexII As Long
Dim position As Long
Dim shuffled(7) As String
For indexI = 0 To UBound(combination)
position = 0
For indexII = 0 To UBound(combination)
If CInt(combination(indexI)) > CInt(combination(indexII)) Then position = position + 1
Next indexII
shuffled(position) = combination(indexI)
Next indexI
CombinationShuffle = shuffled
End Function
Private Function CombinationToString(ByRef shuffledCombination() As String) As String
Dim indexI As Long
Dim tempStr As String
For indexI = 0 To UBound(shuffledCombination)
tempStr = tempStr + "," + shuffledCombination(indexI)
Next indexI
tempStr = Right(tempStr, Len(tempStr) - 1)
CombinationToString = tempStr
End Function
Private Function CombinationNotInRange(ByRef combination As String, Optional ByRef rngToCheck As Range) As String
'Depends
CombinationNotInRange = combination
End Function