Create IF Formula in MS EXCEL - excel

Question

I am trying to write a formula which states if a value is between X% and Y%, then the text in the cell will read Z.
An example would be if a percentage in cell C4 is between 1% and 39%, then cell D4 should read "Unsatisfactory". Similarly, between 40% and 49% would be "Of Concern", etc.,
The values are:
0% = N/A
1%-39% = Unsatisfactory
40%-49% = Of Concern
50%-64% = Satisfactory
65%-79% = Good
80%-89% = Very Good
90%-100% = Excellent

Answer 1

You will need to use AND together with IF. Something like below should work:
=IF(C4>=90%,"Excellent",
IF(AND(C4&lt90%,C4&gt=80%),"Very Good",
IF(AND(C4&lt80%,C4&gt=65%),"Good",
IF(AND(C4&lt65%,C4&gt=50%),"Satisfactory",
IF(AND(C4&lt50%,C4&gt=40%),"Of Concern",
IF(AND(C4&lt40%,C4&gt=1%),"Unsatisfactory",
"N/A"))))))
The formula goes in D4 as you've mentioned.
Edit1:
As mentioned by Andreas, if you really pay attention to the ordering, you can skip the < part. So above, can be simplified to:
=IF(C4>=90%,"Excellent",
IF(C4>=80%,"Very Good",
IF(C4>=65%,"Good",
IF(C4>=50%,"Satisfactory",
IF(C4>=40%,"Of Concern",
IF(C4>=1%,"Unsatisfactory",
"N/A"))))))

Answer 2

Another way of doing this is to use a lookup table. This can use an array constant inside Lookup like this:
=LOOKUP(A1,{0,1,40,50,65,80,90},{"N/A","Unsatisfactory","Of Concern","Satisfactory","Good","Very Good","Excellent"})
Or Vlookup with a table somwhere in your sheet like this
=VLOOKUP(A2,E$2:F$8,2,TRUE)