Excel VBA: If statement with shape fill (favourite button) - excel

Question

I'm trying to make a favourite button, but the stage I'm on is trying to make the button have no fill and upon click have it show a fill. I have also set up a button to insert the star. Code below:
Sub favourite_btn()
Dim star_shp As Shape
Dim clLeft As Double
Dim clTop As Double
Dim clWidth As Double
Dim clHeight As Double
Set cl = Range("A1")
With star_shp
clLeft = cl.Left
clTop = cl.Top
clWidth = 50
clHeight = 50
End With
Set star_shp = ActiveSheet.Shapes.AddShape(msoShape5pointStar, clLeft, clTop, clWidth, clHeight)
With star_shp
.Line.Visible = msoTrue
'.Fill.Visible = msoFalse
.Fill.ForeColor.RGB = 16777215
End With
End Sub
Sub star_fill()
Set ws3 = Sheets("Sheet1")
Dim shp As Shape
Set shp = ActiveSheet.Shapes("5-Point Star 7")
Dim test As String
Debug.Print shp.Fill.ForeColor.RGB
If shp.Fill.ForeColor.RGB = 16777215 Then 'if it is transparent
shp.Fill.ForeColor.RGB = 65535 'make it yellow
test = ws3.Shapes(Application.Caller).TopLeftCell.Offset(0, 1).Value
MsgBox test
Else
shp.Fill.ForeColor.RGB = 16777215 'otherwise back to transparent
End If
End Sub
and I getting an error when I click on the star (which triggers the star_fill macro "the index into the specified collection is out of bounds" and it highlights the line "Set shp = ActiveSheet.Shapes(star_shp)" in the star_Fill sub. I thought it was because I hadn't set the star_shp variable as a public variable but I did that and it still throws this error.
Any ideas? Would appreciate any help! Thanks
EDIT: Updated my code to reflect the changes as suggested in the comments below. Currently I'm trying to not refer to the Star shape by it's specific name and instead refer to it by it's variable as defined in the first subroutine. So my question is around how to make a variable a global variable so a different subroutine can refer to it

Answer 1

Updated code - toggle between yellow and transparent fill:
Sub star_fill()
Dim shp As Shape
Set shp = ActiveSheet.Shapes("5-Point Star 4")
Debug.Print shp.Fill.ForeColor.RGB
If shp.Fill.ForeColor.RGB = 16777215 Then 'if it is transparent
shp.Fill.ForeColor.RGB = 65535 'make it yellow
Else
shp.Fill.ForeColor.RGB = 16777215 'otherwise back to transparent
End If
End Sub
Update #2:
Public variable will only work if you specify it outside of your Sub routine (the variable value always lives and dies within a given routine, if embedded within the routine). So you would need to do do the following:
Public star_shp as Shape
Sub favourite_btn()
...
However, Public variable approach is not error-proof because it could also lose its reference to the shape (for example, closing and opening the file).
An alternative would be to have a routine to create the shape (like your favourite_btn sub) and a completely separate routine to dictate the shapes' behavior. The example below will work for any shape created by your routine and even if your routine is used to create multiple (different) shapes.
Note the use of:
.OnAction = "star_fill" which assigns your star_fill subroutine to a created shape.
Application.Caller which is used to bind user's selected shape to the subroutine star_fill. Thanks to this line we are no longer in need of creating a Public Variable star_shp.
Sub favourite_btn()
Dim star_shp As Shape
Dim clLeft As Double
Dim clTop As Double
Dim clWidth As Double
Dim clHeight As Double
Dim cl As Range
Set cl = Range("A1")
Set star_shp = ActiveSheet.Shapes.AddShape(msoShape5pointStar, cl.Left, cl.Top, 50, 50)
With star_shp
.Line.Visible = msoTrue
'.Fill.Visible = msoFalse
.Fill.ForeColor.RGB = 16777215
.OnAction = "star_fill"
End With
End Sub
Sub star_fill()
Dim star_shp As Shape
On Error Resume Next
Set star_shp = ActiveSheet.Shapes(Application.Caller)
On Error GoTo 0
If Not star_shp Is Nothing Then
If star_shp.Fill.ForeColor.RGB = 16777215 Then 'if it is transparent
star_shp.Fill.ForeColor.RGB = 65535 'make it yellow
Else
star_shp.Fill.ForeColor.RGB = 16777215 'otherwise back to transparent
End If
End If
End Sub

Answer 2

ActiveSheet.shapes accepts a number as input, and finds the nth shape. You already have your shape (star_shp), so there's no need to try to get it again!
If you don't already have it, however, you'll need to find it by iterating through all shapes in the active sheet looking for star_shp. I recommend tagging it somehow with a persistent identifier (naming it, perhaps?) and looking for that, but make sure you test what happens when the user copies it.
Dim shp As Shape
For Each shp In ActiveSheet.shapes
If shp.name = "sparklesthethird" Then
Msgbox("found it")
Exit For
Endif
Next