How can I get
Ʃ 2^n
in via a formula in a cell in Excel, for n from 1 to N when N is a value in a neighbouring cell? I had a look at some related questions here, tried around and ended up with this here, which does not work (generates #NAME?). Can anybody correct this and explain?
=SUMPRODUCT(POW(2,ROW(INDIRECT(CONCATENATE("1:",L41)))))
EDIT: omg, it's the POW which doesn't exist in Excel, should be POWER, how embarrassing. I always stumble across this, coming from C/C++. I thought the problem has to be somewhere in the other functions I never used before. Thanks anyways. I keep the question online though, maybe it is helpful to somebody.
Perhaps:
=SUMPRODUCT(2^ROW(INDEX(A:A,1):INDEX(A:A,A1)))
where A1 holds N
See:
Previous Answer
I still would like to remark that Ʃ 2^n for 1 upto N is 2^(N+1) - 2
=2^(L41+1)-2
=POWER(2, L41+1)-2
That is the POWER function or the ^ operator will do nicely.
BITLSHIFT for 2^N might not work always (floating point, Excel 2010).
Related
Good afternoon,
I am not really an Excel champion so I am having a bit of headache with the last assignment my teacher gave me as I have to use three functions at the same time.
Basically I have to extract the urls from B2 and below and be just "www.cocacola.es" in K2 (just ignore column D and E): https://ibb.co/2S36cC0
I was kinda ok at this point: =MID(B2,FIND("/",B2)+2,LARGO(B2))
Then I got a little bit lost.
I had a look at the forum as well and I actually ended up finding a solution by adding -FIND("/",B3)-32)) at the end of the function but it only works for few rows: https://ibb.co/1n0ty8y
I guess it is something related to LEN but I can't figure how to fix it.
Sorry for the dumb question but it's my last work and I really wanna understand it.
It appears that you want the sub-string between the second / and the third /.
For all your examples the second / is in the eighth position. So we can use:
=MID(MID(A1,9,99),1,FIND("/",MID(A1,9,99))-1)
with the full url in A1.
I'm almost certain this question has been asked before but I couldn't find the answer and have - to be perfectly honest - not the slightest idea what to even call the following problem:
In an excel table I want a sort of false counter whith every number appearing n times.
It will be nested inside a bigger Index formula to basically extract every column n times, to make it look like this
By nesting INT into MOD I managed to get alternating counts:
=MOD(INT(ROW())/2;1) results in the alternating values of 0.5 and 0
However this doesn't seem to lead to a solution for my original problem. So anyone with a name for the functionality I'm looking for or a solution for it has my gratitude.
you were close:
=INDEX(Table1[Value],INT((ROW($ZZ1)-1)/2)+1)
Found another (way more complicated) way to do this:
=INDEX(Table1[Value],INT((ROW()-ROW([Formula])+2)/2))
I need help with the following formula for Excel.
It's not working, the only feedback I'm getting is #VALUE! outcome.
What I'm trying to do is simply:
F5≥-8 = Big,
-3≤F5≤-7.99999= Bigger,
F5≥-2.9999999 = "Blank" <--- No outcome display required
=IF((F5)>=-8, "Big"),IF((F5)>=-3, "Bigger"), IF((F5)<=-1,",")
=IF(F5>=-8, "Big",IF(F5>=-3, "Bigger", IF(F5<=-1,"Biggest","")))
I share the same thought with TotsieMae, you are absolutely right mate. The formula above is by syntax correct but logically not.
Anyway, if the formula involve too many IF functions, then it might be worth to consider an alternate form:
=IFERROR(VLOOKUP(F5,{-8,"Big";-3,"Bigger";-1,"Biggest"},2,TRUE),"Big")
I'm trying to get this into excel: e^(-(2.2/9.58)^2)
According to my graphical calculator AND wolfram alpha this should give: 0.9486
However when I type it in excel with the following formula: =EXP(-(2.2/9.58)^2) I get 1.054
I've tried multiple different things but I still can't get the right answer out of it. What am I doing wrong with the formula in Excel??
Excel seems to mess up the brackets and does some distribution on its own. Very odd.
=EXP(-((2,2/9,58)^2)) should work
By way of some explanation, in Excel (as conventional) the negation operator has precedence over exponentiation. So:
=EXP(-(2.2/9.58)^2)
is treated just as:
=EXP((-2.2/9.58)^2)
or
=EXP(0.052737)
would be, hence resulting in 1.05415. Whereas:
=EXP(-0.052737)
is 0.948629.
Attached is a bowling sheet I have been working on to figure out my averages, and any "free game awards" I may get, as well as patches, etc...
https://dl.dropbox.com/u/3327208/excel/Bowling.xlsx
I am getting a false positive in column S.
Up till S12 the formula seems to work, in where there is a blank, and it shows me getting over 500.
The formula is:
=IF($E12>499,"X","")
Something simple and sweet or so I thought.
Now $E12 has this formula in it, which I don't see why it should affect it at all:
=IF(D12<>0,SUM($B12:$D12),"")
I tried using ISBLANK, but it seems to blow up in my face and not show anything. If someone can help me it would be greatly appreciated, thanks.
A simpler alternative
=IF(N($E12)>499,"X","")
Try this (in E9):
=IF(ISNUMBER(E9),IF($E9>499,"X",""),"")
This is likely a type comparison issue, so this only compares if the cell is actually a number.