Change hyperlink address automatically if the TextToDisplay changes - excel

Question

I need a solution for the hyperlink in Excel. I want to make my entire hyperlink address auto-update if I change the text of the hyperlink.
For example, TextToDisplay of the hyperlink is:
D:/attachment/1000.jpg
then I change the TextToDisplay of the hyperlink to:
D:/attachment/1001.jpg
The hyperlink address changes the same as the display text if I change the text of that hyperlink.

Answer 1

Formula Solution
The easist way would be to use a helper column. For example write your URLs in column A and use the following formula in column B to create the hyperlinks. Everytime you change the URL in column A it will change the hyperlink accordingly.
=HYPERLINK(A:A)
VBA Solution
Alternatively you can use the Worksheet_Change event in VBA.
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cell As Range
For Each Cell In Target
If Cell.Hyperlinks.Count = 1 Then
Cell.Hyperlinks(1).Address = Cell.Value
End If
Next Cell
End Sub
Note that this code applies to all hyperlinks on the worksheet. If you want to limit it to a specific range do the following changes:
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim AffectedRange As Range
Set AffectedRange = Intersect(Target, Me.Range("A:A"))
'limits the code to hyperlinks in column A.
'hyperlinks in other cells than column a are not changed
If Not AffectedRange Is Nothing Then
Dim Cell As Range
For Each Cell In AffectedRange
If Cell.Hyperlinks.Count = 1 Then
Cell.Hyperlinks(1).Address = Cell.Value
End If
Next Cell
End If
End Sub