Finding the occurrence across multiple sheets but with a twist - excel

Question

I wanted to find the number of sick leave of the workers per month. I know that can be achieved easily with =Ifs (), but as you can see from this screenshot:
the sheets may contain the data of other months (late December and early February in this case). There are 12 sheets in total, each contains one month of the year.
I want to write a function that can count the numbers of holidays given by "休息" for each month for each person.
The difficulty is that:
The roaster changes every month and cell position of each person changes, the other problem is:
As mentioned above, each sheet may contain data of other months, which implies the function has to refer to other sheets to count these leaves as well.
Can this be achieved with excel intrinsic functions or should this be done with VBA?

Answer 1

It is real difficult and lot of assumption, to try and understand the problem in unknown language and scanty details. However the solution worked out based of a number of assumption and hope to offer only broad outline to be modified as real time solution according to actual layout of the working file
Assumptions:
Names are in column B
Names start at row 11
For trial only rows up to 35 are used
Days span from column D to AF (Approx)
Column AL is free and used for Countif formula
For solution with excel formulas
Populate column AL of all the monthly sheets with formula
=COUNTIF(D11:AE11,"休息")
In a blank Sheet named “Main” populate column B with list of all the names (may be starting from row 11)
Now Column C representing Month1 may be added with formula
=IF(ISNA(MATCH($B11,Sheet1!$B$11:$B$35,0)), "",INDEX(Sheet1!$AL$11:$AL$35,MATCH($B11,Sheet1!$B$11:$B$35,0),1))
Similarly Column D representing Month1 may be added with formula
=IF(ISNA(MATCH($B12,Sheet2!$B$11:$B$35,0)), "",INDEX(Sheet2!$AL$11:$AL$35,MATCH($B12,Sheet2!$B$11:$B$35,0),1))
And similarly add formula to all the 12 columns pointing towards 12 sheets in the workbook and the create a summation in next blank column
Result Sheet Layout - Main and Month sheets Layout
VBA solution
Add one blank sheet Named “MainVBA” containing list of all the names in the column B starting from row 11 as done in sheet named “Main”. Alternatively this employee list could be created by using dictionary object and collecting all unique names (case sensitive) from all the monthly sheets. For using this code please add reference to “Microsoft Scripting runtime”. (VBA window – Tools – Reference)
Code:
Sub MakeList()
Dim MnWs As Worksheet, Ws As Worksheet
Dim Srw As Long, S1rw As Long
Dim Erw As Long, E1rw As Long
Dim Xname As String
Dim TRw As Long
Dim Cnt As Long
Dim Dict As Dictionary
Set MnWs = ThisWorkbook.Sheets("MainVBA")
Srw = 11 'Starting Row in Result sheet Named "MainVBA"
Erw = MnWs.Cells(Rows.Count, "B").End(xlUp).Row 'Last Row in Result sheet Named "MainVBA"
MnWs.Range("B" & Srw & ":B" & Erw).ClearContents ' Delete last row
Set Dict = New Dictionary
'Get Names from monthly sheets
For Each Ws In ThisWorkbook.Worksheets
If Ws.Name <> "MainVBA" And Ws.Name <> "Main" Then ' Consider all sheets Other than specified two having sick leave data
S1rw = 11
E1rw = Ws.Cells(Rows.Count, "B").End(xlUp).Row 'Last Row in Month sheet
For TRw = S1rw To E1rw
Xname = Ws.Cells(TRw, "B").Value
If Dict.Exists(Xname) = False Then
'Debug.Print Ws.Name, TRw, Xname
Dict.Add Xname, 1
End If
Next
End If
Next Ws
'create list in Sheet "MainVBA" Column B from dictionary
For Cnt = 0 To Dict.Count - 1
MnWs.Cells(Cnt + 11, "B").Value = Dict.Keys(Cnt)
Next
Set Dict = Nothing
End Sub
Code for calculating sick leave count month wise. I used Range B1 to hold the string "休息" (as I refrained to tweak the regional settings etc) , it may be used directly in your VBA module.
Option Explicit
Sub test()
Dim MnWs As Worksheet, Ws As Worksheet
Dim Srw As Long, S1rw As Long, Scol As Long
Dim Erw As Long, E1rw As Long, Ecol As Long
Dim Rw As Long, Col As Long, Xname As String, ChineseStr As String
Dim TRw As Long, XRw As Long, Have As Boolean
Dim Rng As Range, Cnt As Long
Set MnWs = ThisWorkbook.Sheets("MainVBA")
ChineseStr = MnWs.Range("B1").Value 'May use string directly with quotes
Srw = 11 'Starting Row in Result sheet Named "MainVBA"
Erw = MnWs.Cells(Rows.Count, "B").End(xlUp).Row 'Last Row in Result sheet Named "MainVBA"
Scol = 3 'Starting Col Month1 in Result sheet Named "MainVBA"
Ecol = 3 + 11 'End Col Month12 in Result sheet Named "MainVBA"
For Rw = Srw To Erw
Xname = MnWs.Cells(Rw, "B").Value
Col = Scol
For Each Ws In ThisWorkbook.Worksheets
If Ws.Name <> "MainVBA" And Ws.Name <> "Main" Then ' Consider all sheets Other thah specified two having Sick leave data
S1rw = 11
E1rw = Ws.Cells(Rows.Count, "B").End(xlUp).Row 'Last Row in Month sheet
XRw = 0
For TRw = S1rw To E1rw
If Ws.Cells(TRw, "B").Value = Xname Then
XRw = TRw
Exit For
End If
Next
Cnt = 0
If XRw > 0 Then
'Debug.Print Xname, Ws.Name, TRw
Set Rng = Ws.Range("D" & XRw & ":AF" & XRw) ' Col D to AF condsidered having sick leave data
Cnt = Application.WorksheetFunction.CountIf(Rng, ChineseStr) 'sum of month sick leave
End If
MnWs.Cells(Rw, Col).Value = Cnt
Col = Col + 1
End If
Next Ws
Next Rw
End Sub
To make this code working, it may be required to modify all the sheets details like sheets name, row, column details etc. Feel free to feedback if code is some where near to your objective and actual scenario.