Open files in a loop using Dir - excel

Question

I want to open a file, copy from it then paste to another document, copy from that and paste back into the opened document.
I converted the file names to strings and it recognizes that but says they don't exist.
Dim StrFile As String
'Debug.Print "in LoopThroughFiles. inputDirectoryToScanForFile: ", inputDirectoryToScanForFile
StrFile = Dir("H:\Open Work book" & "\" & "*.xlsx")
Do While Len(StrFile) > 0
StrFile = Dir
'Opens The File In The folder
Workbooks.Open StrFile
This should open the files in a loop. It says
Sorry, we couldn't find CTM Service Reach.xlsx. Is it possible it was moved renamed or deleted?

Answer 1

When you execute
StrFile = Dir("H:\Open Work book" & "\" & "*.xlsx")
strfile gets filled with the first file matching the pattern. You check that something is returned
Do While Len(StrFile) > 0
but then you change strfile into the next file meeting the pattern - throwing away the first file's name
StrFile = Dir
Then you attempt to open the file without specifying where it is
Workbooks.Open StrFile
what you should be doing is
StrFile = Dir("H:\Open Work book" & "\" & "*.xlsx")
Do While Len(StrFile) > 0
Workbooks.Open "H:\Open Work book" & "\" & StrFile
StrFile = Dir
Loop

Answer 2

I know, you have your solution but, hey, like the Romans used to say: variatio delectat. Here's another way of doing this:
Sub test()
Dim objFSO As Object
Dim objFolder As Object
Dim objFile As Object
Dim strDir As String
Dim wkb As Workbook
strDir = "H:\Open Work book\"
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(strDir)
For Each objFile In objFolder.Files
If objFSO.GetExtensionName(objFile) = "xlsx" Then
Set wkb = Workbooks.Open(objFile)
// You code here
End If
Next
End Sub