Get Excel cell properties that have been copied to the clipboard - excel

Question

I'm trying to copy the values from multiple cells into one cell. If I only wanted to have the values of the cells combined, I would use something like
Dim str as string = My.Computer.ClipBoard.GetText
oxlapp.ActiveCell.Value = str
However
In this case I need to include html tagging, to create a table and I also want to include formatting like bold, italic and underlined. Therefore, instead of just the text from the clipboard, I need to know some cell properties.
I know that they should be there, because you can copy/paste entire cells of course.
So far I tried getting the Excel cells by using
My.Computer.Clipboard.GetData(XlClipboardFormat.xlClipboardFormatTable)
and
My.Computer.Clipboard.GetData(XlClipboardFormat.xlClipboardFormatCSV)
but while debugging I noticed that both of them returned Nothing.
Does someone know how I can get all cell properties from the clipboard?
To make it more clear, I want this
To turn into this:
If there is any other way than using the clipboard, I would be happy to try.

Answer 1

You need to use another format from clipboard - XML Spreadsheet. The copied data is contained in special XML with its own structure and attributes. Let's take the following sheet's data:
As you see, every cell has some formatting. The XML for this data is the following:
<ss:Workbook xmlns="urn:schemas-microsoft-com:office:spreadsheet"
xmlns:o="urn:schemas-microsoft-com:office:office"
xmlns:x="urn:schemas-microsoft-com:office:excel"
xmlns:ss="urn:schemas-microsoft-com:office:spreadsheet"
xmlns:html="http://www.w3.org/TR/REC-html40">
<ss:Styles>
<ss:Style ss:ID="Default" ss:Name="Normal">
<ss:Alignment ss:Vertical="Bottom"/>
<ss:Borders/>
<ss:Font ss:FontName="Calibri" x:CharSet="204" x:Family="Swiss" ss:Size="11" ss:Color="#000000"/>
<ss:Interior/>
<ss:NumberFormat/>
<ss:Protection/>
</ss:Style>
<ss:Style ss:ID="s62">
<ss:Interior ss:Color="#FFFF00" ss:Pattern="Solid"/>
</ss:Style>
<ss:Style ss:ID="s63">
<ss:Font ss:FontName="Calibri" x:CharSet="204" x:Family="Swiss" ss:Size="11" ss:Color="#000000" ss:Bold="1"/>
</ss:Style>
<ss:Style ss:ID="s64">
<ss:Font ss:FontName="Calibri" x:CharSet="204" x:Family="Swiss" ss:Size="11" ss:Color="#0000FF"/>
</ss:Style>
<ss:Style ss:ID="s65">
<ss:Font ss:FontName="Calibri" x:CharSet="204" x:Family="Swiss" ss:Size="11" ss:Color="#000000" ss:Italic="1"/>
</ss:Style>
</ss:Styles>
<ss:Worksheet ss:Name="Sheet1">
<ss:Table ss:ExpandedColumnCount="2" ss:ExpandedRowCount="2" ss:DefaultRowHeight="15">
<ss:Row>
<ss:Cell ss:StyleID="s62">
<ss:Data ss:Type="String">A</ss:Data>
</ss:Cell>
<ss:Cell ss:StyleID="s63">
<ss:Data ss:Type="String">1</ss:Data>
</ss:Cell>
</ss:Row>
<ss:Row>
<ss:Cell ss:StyleID="s64">
<ss:Data ss:Type="String">B</ss:Data>
</ss:Cell>
<ss:Cell ss:StyleID="s65">
<ss:Data ss:Type="String">2</ss:Data>
</ss:Cell>
</ss:Row>
</ss:Table>
</ss:Worksheet>
</ss:Workbook>
As you see, you have all information about formatting in corresponding styles. For instace, value A in A1 cell has style s62 (StyleID attribute) - you can find the appropriate Style node with this number in Styles node. The structure of rows and columns in this XML is implicit - i.e. you won't see indexes of rows and columns - you need to calculate them yourself. For instance, the second Cell node in first Row node is first row, second column.
The following code generates data in the picture above and retrieves appropriate elements to manipulate.
A word of caution 1. If you take a look closely, the Workbook node has two urn:schemas-microsoft-com:office:spreadsheet namespaces: first is default and second is with prefix ss. Just remember - you always need to use ss prefix!
A word of caution 2. This method has one drawback - it doesn't understand hidden rows (manually or by autofilter) and columns! It includes hidden rows/columns, too!
Imports <xmlns:ss="urn:schemas-microsoft-com:office:spreadsheet">
Imports <xmlns:x="urn:schemas-microsoft-com:office:excel">
Sub GetCellsWithFormat()
'// Create new Excel app
Dim xlApp = New Excel.Application With {.Visible = True}
Dim book = xlApp.Workbooks.Add()
Dim sheet = DirectCast(book.Sheets(1), Excel.Worksheet)
'// Apply some formatting
With sheet
.Range("A1").Interior.Color = Excel.XlRgbColor.rgbYellow
.Range("B1").Font.Bold = True
.Range("A2").Font.Color = Excel.XlRgbColor.rgbBlue
.Range("B2").Font.Italic = True
'// Add some values
Dim arr = Array.CreateInstance(GetType(String), {2, 2}, {1, 1})
arr(1, 1) = "A" : arr(1, 2) = "1"
arr(2, 1) = "B" : arr(2, 2) = "2"
With .Range("A1:B2")
.Value = arr
.Copy() '//Copy cells to clipboard
End With
Dim xml As XElement
Using xml_stream = DirectCast(Clipboard.GetData("XML Spreadsheet"), Stream)
'// Get rid of last character (new line) to avoid parsing error
xml_stream.SetLength(xml_stream.Length - 1)
xml = XElement.Load(xml_stream)
End Using
'// Get any element you need
Dim styles = xml.<ss:Styles>(0)
Dim table = xml.<ss:Worksheet>.<ss:Table>(0)
Dim rows = table.<ss:Row>
'// Do something with this data
End With
End Sub
UPDATE
In fact, you don't need to use clipboard to get this XML - you just need to use xlRangeValueXMLSpreadsheet value of Value property:
With sheet
'// Same code...
With .Range("A1:B2")
.Value = arr
'.Copy() '//No need to copy!
End With
Dim xml_string = CStr(.Range("A1:B2").Value(Excel.XlRangeValueDataType.xlRangeValueXMLSpreadsheet))
'// Again, exclude last character
Dim xml = XElement.Parse(xml_string.Substring(0, xml_string.Length - 1))
'// Get any element you need
Dim styles = xml.<ss:Styles>(0)
Dim table = xml.<ss:Worksheet>.<ss:Table>(0)
Dim rows = table.<ss:Row>
'// Do something with this data
End With

Answer 2

When I want to allow data copied from Excel into a custom windows app that I wrote, I use GetText() instead of GetData().
Dim ClipboardText As String = Nothing
ClipboardText = My.Computer.Clipboard.GetText()
If it is multiple cells that are copied to the Clipboard from Excel, they could be seperated by vbTab and vbCrLf depending on the selection.