Parse certain values from Google Maps XML to Excel cells - excel

Question

I have a link "https://maps.googleapis.com/maps/api/distancematrix/xml?origins=..." that I access to get XML file data.
XML file:
<DistanceMatrixResponse>
<status>OK</status>
<origin_address>London, UK</origin_address>
<destination_address>Manchester, UK</destination_address>
<row>
<element>
<status>OK</status>
<duration>
<value>14735</value>
<text>4 hours 6 mins</text>
</duration>
<distance>
<value>335534</value>
<text>336 km</text>
</distance>
</element>
</row>
</DistanceMatrixResponse>
XML file structure is always the same. I need to get <text>4 hours 6 mins</text> and <text>336 km</text> in form of 4,6 to cell A1 and 336 to cell A2 lets say "Contact database". Also problem here is that <text>4 hours 6 mins</text> sometimes can be <text>1 hour 3 min</text>. I can do it with formula but is it even possible with VBA?
I have managed to make it work so that the whole XML file data is in cell A1. However not able to separate what I need and paste to two different cells.
Sub GoogleAPI1()
Dim xmlhttp As Object
Set xmlhttp = CreateObject("MSXML2.serverXMLHTTP")
Dim myurl As String
myurl = "https://maps.googleapis.com/maps/api/distancematrix/xml?origins=" & ThisWorkbook.Worksheets("Contact database").Range("R86").Value _
& "&destinations=" & ThisWorkbook.Worksheets("Contact database").Range("R87").Value & "&mode=" & ThisWorkbook.Worksheets("Contact database").Range("R88").Value _
& "&key=" & ThisWorkbook.Worksheets("Contact database").Range("R82").Value
xmlhttp.Open "GET", myurl, False
xmlhttp.send
ThisWorkbook.Worksheets("Contact database").Range("R92") = xmlhttp.responseText
End Sub

Answer 1

Here's one way to use VBA to get the results you describe.
I extracted the node information, and then processed it using Regular Expressions to get it into the format you described.
Could probably do it more efficiently, and with more or different error-checking, but this might get you started.
Option Explicit
Sub getDurDist()
Dim xmlDoc As DOMDocument60
Dim xmlNode As IXMLDOMNode
Dim sTemp As String
Dim RE As Object, MC As Object
Dim rDest As Range
Set xmlDoc = New DOMDocument60
'hard coded here. Change to suit
Set rDest = Range("B1:C1")
rDest.Clear
xmlDoc.LoadXML Range("a1")
Set xmlNode = xmlDoc.SelectSingleNode("//duration/text")
sTemp = xmlNode.Text
Set RE = CreateObject("vbscript.regexp")
With RE
.Global = True
.Pattern = "\d+"
If .test(sTemp) = True Then
Set MC = .Execute(sTemp)
rDest(1, 1) = MC(0) & "," & MC(1)
End If
End With
Set xmlNode = xmlDoc.SelectSingleNode("//distance/text")
sTemp = xmlNode.Text
With RE
If .test(sTemp) = True Then
Set MC = .Execute(sTemp)
rDest(1, 2) = MC(0)
End If
End With
End Sub