Copy data from another workbook without hardcoding the file path - excel

Question

I am trying to copy and transpose data from one workbook to another. Each week the file to copy information from is updated to a new workbook. In my macro I callout "Week of 06-17-19 WGN WB A-line.xlsm".
I would like to manually open the sheet to copy the data without having to hard-code the new date.
Could I use the ActiveWorkbook function to call the new open sheet?
Sub copytranspose()
Application.ScreenUpdating = False
Dim i As Integer
Dim Column As Integer
Dim Row As Integer
Row = 5
Column = 8
For i = 1 To 6
Workbooks("Week of 06-17-19 WGN WB A-line.xlsm").Worksheets("WEEKLY").Cells(10, Column).Copy
Column = Column + 2
Workbooks("copy transpose.xlsm").Worksheets("sheet1").Cells(Row,3).PasteSpecial Paste:=xlPasteValues
Row = Row + 1
Next i
End Sub

Answer 1

Solution 1
You can avoid hard-coding in the date into the code by storing the date of the file you want to open in a cell. Say you have a sheet called "config" and in range "A1" you have the date "06-24-19". Assuming you have both files in the same directory you could write something like this
Dim i As Integer
Dim Column As Integer
Dim Row As Integer
Row = 5
Column = 8
Dim currFileDate As String
currFileDate = Format(ThisWorkbook.Worksheets("Config").Range("A1").Value, "mm-dd-yy") '' Get the date typed in
Dim srcDataWB As Workbook
'' Open the workbook automatically with the file date of A1
Set srcDataWB = Workbooks.Open(ThisWorkbook.Path & "\Week of " & currFileDate & " WGN WB A-Line.xlsm")
For i = 1 To 6
srcDataWB.Worksheets("WEEKLY").Cells(10, Column).Copy
Column = Column + 2
'' If this is the same workbook that the code is stored
'' I suggest switching out Workbooks("copy transpose.xlsm") for ThisWorkbook
Workbooks("copy transpose.xlsm").Worksheets("sheet1").Cells(Row, 3).PasteSpecial Paste:=xlPasteValues
Row = Row + 1
Next i
Solution 2
Alternatively, if what you really want is to just match an already opened workbook that matches the pattern of "Week of * WGN WB A-line.xlsm" then the following will work. HOWEVER it's not bullet-proof since you could potentially have two workbooks open that match that pattern.
Sub DoStuff()
Dim i As Integer
Dim Column As Integer
Dim Row As Integer
Row = 5
Column = 8
Dim srcDataWB As Workbook
'' Get the already opened workbook that matches the pattern 'Week of * WGN WB A-line.xlsm'
Set srcDataWB = GetSrcDataWB
For i = 1 To 6
srcDataWB.Worksheets("WEEKLY").Cells(10, Column).Copy
Column = Column + 2
'' If this is the same workbook that the code is stored
'' I suggest switching out Workbooks("copy transpose.xlsm") for ThisWorkbook
Workbooks("copy transpose.xlsm").Worksheets("sheet1").Cells(Row, 3).PasteSpecial Paste:=xlPasteValues
Row = Row + 1
Next i
End Sub
Function GetSrcDataWB() As Workbook
Dim wbName As String
Dim currWB As Workbook
For Each currWB In Application.Workbooks
If currWB.name Like "Week of * WGN WB A-line.xlsm" Then
Set GetSrcDataWB = currWB
Exit For '' No more need to loop
End If
Next
End Function