Reading cell value - excel

Question

So I have created a macro which is sending an email via outlook. I am stuck at some point. I need to include new cell values and corresponding cell values on top of the column in the body of an email. So basically I need my macro to read those two values.
This is my module:
Sub SendEmail()
Dim olApp As Outlook.Application
Set olApp = CreateObject("Outlook.Application")
Dim olMail As Outlook.MailItem
Set olMail = olApp.CreateItem(olMailItem)
'So I want to send an email with cell new value and top of the column
'value corresponding to that cell
'Example: I wanna change cell C3 from A to X and I want to include
'that change in body of my email automatically
'So it reads "New cell value is X on 3-06"
olMail.To = "*****#*****.com"
olMail.Subject = "Look what has been changed"
olMail.Body = "Hi" & vbNewLine & vbNewLine & _
"New cell value is <Here is new cell value> on <Top of the column
of that cell value> " & vbNewLine & vbNewLine & _
"BR"
olMail.Send
End Sub
And this is my macro:
Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Target.Worksheet.Range("A3:AP3")) Is Nothing Then SendEmail
End Sub
And this is a part of the worksheet I am working on:

Answer 1

One of the problems you are facing is that the Target can be multiple cells and one Worksheet_Change change can be over multiple cells at the same time, not just once cell. You could check if the Target is one cell size, and do nothing if more than 1, 1 size, but then you would loose that change or parts of it at least.
An approach would be to hold a history of the changes, and send that email even if the changes are over multiple cells at once.
With that in mind, you should create an additional sheet that holds last changes, say sheet History Sheet.
In the sheet your working on, place in the code part of the sheet:
Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Target.Worksheet.Range("A3:AP3")) Is Nothing Then
checkHistory Target.Worksheet.Range("A3:AP3")
End If
End Sub
In any module in the same workbook, add this:
Sub checkHistory(rng As Range)
Dim wsHistory As Worksheet: Set wsHistory = ThisWorkbook.Sheets("History Sheet")
Dim arrData As Variant, arrHistory As Variant
Dim R As Long, C As Long
Dim bChanges As Boolean
arrData = rng.Offset(-2).Resize(3)
arrHistory = wsHistory.Range(rng.Offset(-2).Resize(3).Address)
Dim arrChanges() As String: ReDim arrChanges(LBound(arrData) To UBound(arrData), LBound(arrData, 2) To UBound(arrData, 2))
For C = LBound(arrData, 2) To UBound(arrData, 2)
If arrData(3, C) <> arrHistory(3, C) Then
arrChanges(3, C) = arrData(3, C)
If Not bChanges Then bChanges = True
End If
Next C
If bChanges Then
Dim strNewVal As String, strHeading As String
wsHistory.Range(rng.Offset(-2).Resize(3).Address) = arrData
For C = LBound(arrChanges, 2) To UBound(arrChanges, 2)
If arrChanges(3, C) <> "" Then
strNewVal = strNewVal & ", " & arrChanges(3, C) 'new values
strHeading = strHeading & ", " & arrData(1, C) 'heading
End If
Next C
strNewVal = Right(strNewVal, Len(strNewVal) - 2)
strHeading = Right(strHeading, Len(strHeading) - 2)
SendEmail strNewVal, strHeading
End If
End Sub
Sub SendEmail(strNewVal As String, strHeading As String)
Dim olApp As Outlook.Application
Set olApp = CreateObject("Outlook.Application")
Dim olMail As Outlook.MailItem
Set olMail = olApp.CreateItem(olMailItem)
olMail.To = "*****#*****.com"
olMail.Subject = "Look what has been changed"
olMail.Body = "Hi" & vbNewLine & vbNewLine & _
"New cell value is " & strNewVal & " on " & strHeading & vbNewLine & vbNewLine & _
"BR"
olMail.Send
End Sub
With the above, you would send that email regardless if the change is over 1 cell, or more, as comma separated values.

Answer 2

Some small changes:
Sub SendEmail(rng As Range)
Dim olApp As Outlook.Application, c As Range, bdy
If rng Is Nothing Then Exit Sub '<< nothing to report
Set olApp = CreateObject("Outlook.Application")
Dim olMail As Outlook.MailItem
Set olMail = olApp.CreateItem(olMailItem)
olMail.To = "*****#*****.com"
olMail.Subject = "Look what has been changed"
bdy = "Hi" & vbNewLine & vbNewLine
'check each changed cell
For Each c in rng.Cells
bdy = bdy & "New cell value is '" & c.Value & _
"' on " & c.EntireColumn.Cells(1).Value & _
vbNewLine & vbNewLine
Next c
olMail.Body = bdy & vbNewLine & vbNewLine & "BR"
olMail.Send
End Sub
Event handler:
Private Sub Worksheet_Change(ByVal Target As Range)
SendEmail Application.Intersect(Target, Me.Range("A3:AP3"))
End Sub