How to exclude the topmost selection from Application.Selection.Areas? - excel

Question

I want to exclude the topmost selection from a list of selection(CTRL + Click) in a column. For example, if I selected Cell V12 + V10 + V14 + V9. The topmost selection is V9. I have this code that loops through all the selected cells but I need to exclude the topmost selection (i.e V9).
Here's the working code:
Dim rngPart as Range
For Each rngPart in Application.Selection.Areas
MsgBox rngPart.Address
Next
I need help with excluding the topmost selection

Answer 1

I would break this up into a few functions to compose it together.
First I would want a function to find the top range based on its row. To do this we just need a simple loop and assign the range if it is less than the previous cell.
Private Function getTopRange(ByRef source As Range) As Range
Dim cell As Range
For Each cell In source
If getTopRange Is Nothing Then
Set getTopRange = cell
End If
If cell.Row < getTopRange.Row Then
Set getTopRange = cell
End If
Next cell
End Function
Then I would create the function that would return the range excluding the top one.
Again to do that, we just need a simple loop. If it isn't the top cell, then union it to our return range value.
Private Function excludeTopRange(ByRef source As Range) As Range
Dim topRange As Range
Set topRange = getTopRange(source)
Dim cell As Range
For Each cell In source
' Only add if not the top cell
If cell.Address <> topRange.Address Then
If excludeTopRange Is Nothing Then
Set excludeTopRange = cell
Else
Set excludeTopRange = Union(excludeTopRange, cell)
End If
End If
Next cell
End Function
Putting it all together you just call our new function!
Private Sub test()
Dim source As Range
Set source = Application.Selection
Dim excluded As Range
Set excluded = excludeTopRange(source)
MsgBox excluded.Address
End Sub
It's a good design to try and keep your functions small and reusable like this. It's easier to read, debug, test, and reuse!