Copy values from 30 book to one book - Excel VBA - excel

Question

I am trying to copy values from 30 books of excel to another book excel , but I am not sure how to reference the 30 books because they have different name.Also I don't know how to reference the file of excel that I want to close.
I am running the macro from the book of excel that it will have all the values from the other excels.
My problems are:
Don't know how to reference the Excel worbooks that will open because they have different names.
How to paste the values with offset.
I have this code:
Sub MacroPrueba4()
'Paso 1: Declarar las variables
Dim Archivos As String
Dim vals As Variant
Worksheets("Hoja1").Range("A3:A7").Copy
vals = Worksheets("Hoja1").Range("A2:F14").Value
Archivos = Dir("C:\Users\fernandofernandez\Desktop\Prueba\*.xlsx")
Do While Archivos <> “”
'Paso 3: Open the books one by one
Workbooks.Open "C:\Users\fernandofernandez\Desktop\Prueba\" & Archivos
'code
vals = Worksheets(1).Range("E2").Value
' this is something i use to paste the format of the last column format
Workbooks("libro2").Range("C10").End(xlToRight).Select
Selection.EntireColumn.Select
Selection.Copy
ActiveSheet.Range("C10").End(xlToRight).Offset(0, 1).Select
Selection.EntireColumn.Select
ActiveSheet.Paste
'Selection.Paste
' this is where I will paste de value
' is this right??
ActiveSheet.Range("C10").End(xlToRight).Offset(0, 1).Select
Selection.Value = vals
'this close the active excel, but I think it would close the excel that I am pasting the values, because it would be the activeworkbook. I want to close only the 30 excels that will open in the loop.
ActiveWorkbook.Close SaveChanges:=True
Archivos = Dir
Loop
End Sub

Answer 1

The function Workbooks.Open returns the workbook open, so you can write :
my_workbook = Workbooks.Open "C:\Users\fernandofernandez\Desktop\Prueba\" & Archivos
' Your code
my_workbook.Close SaveChanges:=True
With this you are sure that you close the right book.
For assign values don't use select if you want a clean code.
You can do :
ActiveSheet.Range("C10").End(xlToRight).Offset(0, 1).value = vals
You're welcome.

Answer 2

Merge data from all workbooks in a folder.
Sub Basic_Example_1()
Dim MyPath As String, FilesInPath As String
Dim MyFiles() As String
Dim SourceRcount As Long, Fnum As Long
Dim mybook As Workbook, BaseWks As Worksheet
Dim sourceRange As Range, destrange As Range
Dim rnum As Long, CalcMode As Long
'Fill in the path\folder where the files are
MyPath = "C:\Users\Ron\test"
'Add a slash at the end if the user forget it
If Right(MyPath, 1) <> "\" Then
MyPath = MyPath & "\"
End If
'If there are no Excel files in the folder exit the sub
FilesInPath = Dir(MyPath & "*.xl*")
If FilesInPath = "" Then
MsgBox "No files found"
Exit Sub
End If
'Fill the array(myFiles)with the list of Excel files in the folder
Fnum = 0
Do While FilesInPath <> ""
Fnum = Fnum + 1
ReDim Preserve MyFiles(1 To Fnum)
MyFiles(Fnum) = FilesInPath
FilesInPath = Dir()
Loop
'Change ScreenUpdating, Calculation and EnableEvents
With Application
CalcMode = .Calculation
.Calculation = xlCalculationManual
.ScreenUpdating = False
.EnableEvents = False
End With
'Add a new workbook with one sheet
Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
rnum = 1
'Loop through all files in the array(myFiles)
If Fnum > 0 Then
For Fnum = LBound(MyFiles) To UBound(MyFiles)
Set mybook = Nothing
On Error Resume Next
Set mybook = Workbooks.Open(MyPath & MyFiles(Fnum))
On Error GoTo 0
If Not mybook Is Nothing Then
On Error Resume Next
With mybook.Worksheets(1)
Set sourceRange = .Range("A1:C1")
End With
If Err.Number > 0 Then
Err.Clear
Set sourceRange = Nothing
Else
'if SourceRange use all columns then skip this file
If sourceRange.Columns.Count >= BaseWks.Columns.Count Then
Set sourceRange = Nothing
End If
End If
On Error GoTo 0
If Not sourceRange Is Nothing Then
SourceRcount = sourceRange.Rows.Count
If rnum + SourceRcount >= BaseWks.Rows.Count Then
MsgBox "Sorry there are not enough rows in the sheet"
BaseWks.Columns.AutoFit
mybook.Close savechanges:=False
GoTo ExitTheSub
Else
'Copy the file name in column A
With sourceRange
BaseWks.cells(rnum, "A"). _
Resize(.Rows.Count).Value = MyFiles(Fnum)
End With
'Set the destrange
Set destrange = BaseWks.Range("B" & rnum)
'we copy the values from the sourceRange to the destrange
With sourceRange
Set destrange = destrange. _
Resize(.Rows.Count, .Columns.Count)
End With
destrange.Value = sourceRange.Value
rnum = rnum + SourceRcount
End If
End If
mybook.Close savechanges:=False
End If
Next Fnum
BaseWks.Columns.AutoFit
End If
ExitTheSub:
'Restore ScreenUpdating, Calculation and EnableEvents
With Application
.ScreenUpdating = True
.EnableEvents = True
.Calculation = CalcMode
End With
End Sub
See the link below for all details.
https://www.rondebruin.nl/win/s3/win008.htm
You may want ton consider this utility as well.
https://www.rondebruin.nl/win/addins/rdbmerge.htm