How to open a userform through a custom excel ribbon - excel

Question

I am trying to open a userform through a custom excel ribbon. When I click the button in the ribbon it begins initializing and on the workbooks.open function it sends the code to the queryclose sub. The show userform code is below:
Sub RemoveFixture_onAction(control As IRibbonControl)
SelectedCompType = Fixture
Set EditComp = New ufUpdateComp
With EditComp
.Top = Application.Top + 125
.Left = Application.Left + 25
.Show
End With
End Sub
When the code begins the userform_Initialize code it ends up moving to the query_close sub. The code for that is below:
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
'If wb Is Nothing Then UserForm_Initialize
wb.Close False
End Sub
As seen above, in the commented out section, I tried to return to the initialize sub when the code moved to the queryclose function. It moves to the queryclose sub when it runs the workbooks.open code and it says that the wb is nothing. I have tried opening the workbook separately and then setting the workbook as ActiveWorkbook. I also tried:
do while wb is nothing
set wb = ActiveWorkbook
loop
This loop ran endlessly until I had to manually cancel it.
It was originally set wb = workbooks.open(Test)
Private Sub UserForm_Initialize()
Workbooks.Open Test, , , , , DynoCompPassword, True
Set wb = ActiveWorkbook
Set ws = wb.Worksheets("Info")
Set ws = wb.Worksheets("Info")
Set wsC = wb.Worksheets("Calipers")
Set wsF = wb.Worksheets("Fixtures")
Set wsW = wb.Worksheets("Wheel Sims")
ws.Visible = True
wsC.Visible = True
wsF.Visible = True
btnCreate.Enabled = False
Dim rng As Range
lblLocation.Visible = False
tbLocation.Visible = False
Me.cbOut.AddItem "Sent To"
Me.cbOut.AddItem "Scrapped"
Me.cbOut.AddItem "Returned"
Me.btnCreate.Enabled = True
For Each rngprojectcode In ws.Range("ProjectCode")
Me.cbProjectCode.AddItem rngprojectcode.Value
Next rngprojectcode
Set ProjCodeDictionary = New Dictionary 'Create the dictionary
Dim i As Integer
Dim j As Integer
Dim ProjCodeString As String
Dim AssociatedCodes As ProjectCodeList
If ws Is Nothing Then Exit Sub
ProjCodeDictionary.CompareMode = vbTextCompare 'Make the .exists method case insensitive in an attempt to avoid duplicate values
Set AssociatedCodes = New ProjectCodeList 'create the class module which will split up the associated codes into individual values
i = 1
While ws.Range("F1").Offset(i, 0) <> ""
With AssociatedCodes
.SetCodes = CStr(ws.Range("F1").Offset(i, 0).Value)
For j = 1 To .NumCodes
ProjCodeDictionary.Add .ProjCode(j), i 'key, item
Next j
End With
i = i + 1
Wend
If SelectedCompType = Fixture Then
Me.lblCompNum.Caption = "Fixture ID"
Me.btnCreate.Caption = "Update Fixture"
'Automation Error occurs here
Me.Caption = "Edit Fixture"
Me.frChangeFrame.Height = 65
Me.frChangeFrame.Caption = "Bolt Circle"
Me.cbPartNum.Text = "FIX"
For Each rng In wsF.Range("FixtureNum")
Me.cbPartNum.AddItem rng.Value
Next rng
Set tbNumStuds = frChangeFrame.Controls.Add("Forms.TextBox.1", , "True")
To clarify, the queryclose sub should only be activated when the red box with the X is pressed in the userform. It is a built in function of the userform.

Answer 1

The only time the queryclose sub should run is when the X button is pressed on the userform.
But that's not how QueryClose works. The UserForm.QueryClose event is fired whenever the form is about to be closed, and its parameters give you means to cancel it, depending on what prompted it to close.
What you want is to run wb.Close False conditionally, when the CloseMode parameter value is vbFormControlMenu (the X button - see QueryClose constants):
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
If CloseMode = vbFormControlMenu Then
wb.Close False
End If
End Sub
I tried to return to the initialize sub when the code [...]
Don't do this. Event handlers are meant to be invoked by VBA itself, not user code. If you need to invoke logic that you've implemented in an event handler, refactor the code out of the handler and into its own procedure instead:
Private Sub UserForm_Initialize()
DoInitializationStuff
End Sub
Private Sub DoInitializationStuff()
'...
End Sub
Lastly, the UserForm.Initialize event is fired well before the form is shown.
Set EditComp = New ufUpdateComp ' <~ initialize handler runs before this instruction returns
With EditComp
.Top = Application.Top + 125
.Left = Application.Left + 25
.Show
End With
Note that you don't need to declare the local variable if you're only using it in a With block - have the block hold the object reference instead:
With New ufUpdateComp ' <~ initialize handler runs before this instruction returns
.Top = Application.Top + 125
.Left = Application.Left + 25
.Show
End With
If you want DoInitializationStuff to run after the form is shown, invoke it in the Activate event.