change background colour for partial row dependant on 1 Cell - excel

Question

So I'm at the last hurdle with my VBA coding. I'm creating a schedule for several different countries and need the background for cells A7:H300 to colour automatically depending on a value within the same specific row being the country code.
I know I could use conditional formatting but the colours do not copy and paste into a separate sheet using that method.
The code I have below works but it colours D:K instead of the expected A:H - The value is in Row D so I'm guessing that's the problem but I can't workout a way around it.
Thank you for you help :)
Sub ChangeColour()
Set PC = Range("A:H")
For Each cell In PC
If cell.Value = "BEZEE" Then cell.Columns("A:H").Interior.ColorIndex = 40
If cell.Value = "BEANR" Then cell.Columns("A:H").Interior.ColorIndex = 40
If cell.Value = "DEBRH" Then cell.Columns("A:H").Interior.ColorIndex = 37
If cell.Value = "FRLEH" Then cell.Columns("A:H").Interior.ColorIndex = 38
If cell.Value = "GBBRS" Then cell.Columns("A:H").Interior.ColorIndex = 35
If cell.Value = "GBLPL" Then cell.Columns("A:H").Interior.ColorIndex = 35
If cell.Value = "GBSOU" Then cell.Columns("A:H").Interior.ColorIndex = 35
If cell.Value = "NLRTM" Then cell.Columns("A:H").Interior.ColorIndex = 40
If cell.Value = "FIHNO" Then cell.Columns("A:H").Interior.ColorIndex = 36
If cell.Value = "SEGOT" Then cell.Columns("A:H").Interior.ColorIndex = 36
If cell.Value = "ZADUR" Then cell.Columns("A:H").Interior.ColorIndex = 45
If cell.Value = "ZAELS" Then cell.Columns("A:H").Interior.ColorIndex = 45
If cell.Value = "ZAPLZ" Then cell.Columns("A:H").Interior.ColorIndex = 45
Next
End Sub

Answer 1

You're addressing the wrong range. The way you're attempting to do it effectively acts as an Offset from the referenced Cell. A better of way of writing it as well would be the following:
Public Sub ChangeColour()
Dim PC As Range, LastRow As Range
Dim ColorIndexValue As Long
Dim cell
' Set your desired range - Should reference Relevant worksheet as well
Set PC = Range("A7:H1000")
' Find last used row in that range - This will help limit the number of loops on a fixed range and speed up execution
Set LastRow = PC.Find(what:="*", _
after:=Cells(PC.Row, PC.Column), _
lookat:=xlWhole, _
LookIn:=xlValues, _
searchorder:=xlByRows, _
searchdirection:=xlPrevious)
If Not LastRow Is Nothing Then
' Resize PC to actual used range instead of working on entire sheet
Set PC = PC.Cells(1).Resize(LastRow.Row, PC.Columns.Count)
' Loop through all cells in range in Column D
For Each cell In PC.Columns("D").Cells
' Set ColorIndexValue variable based on cell value
Select Case cell.Value2
Case "GBBRS", "GBLPL", "GBSOU": ColorIndexValue = 35
Case "FIHNO", "SEGOT": ColorIndexValue = 36
Case "BEANR", "DEBRH": ColorIndexValue = 37
Case "FRLEH": ColorIndexValue = 38
Case "BEZEE", "NLRTM": ColorIndexValue = 40
Case "ZADUR", "ZAELS", "ZAPLZ": ColorIndexValue = 45
Case Else: ColorIndexValue = 0
End Select
' Set cell Color. Skip 0 as assume cell is 0 by default
If ColorIndexValue > 0 Then
' Calculates applicable range from cell and PC context
With Range(cell.Offset(0, PC.Cells(1).Column - cell.Column), cell.Offset(0, PC.Cells(1, PC.Columns.Count).Column - cell.Column))
.Interior.ColorIndex = ColorIndexValue
End With
End If
Next cell
End If
End Sub

Answer 2

I think you could try:
Option Explicit
Sub test()
Dim Lastrow As Long, i As Long
With ThisWorkbook.Worksheets("Sheet1")
Lastrow = .Cells(.Rows.Count, "D").End(xlUp).Row
For i = 1 To Lastrow
If .Range("D" & i).Value = "BEZEE" Or .Range("D" & i).Value = "BEANR" Or .Range("D" & i).Value = "NLRTM" Then
.Range("A" & i & ":H" & i).Interior.ColorIndex = 40
ElseIf .Range("D" & i).Value = "DEBRH" Then
.Range("A" & i & ":H" & i).Interior.ColorIndex = 37
ElseIf .Range("D" & i).Value = "FRLEH" Then
.Range("A" & i & ":H" & i).Interior.ColorIndex = 38
ElseIf .Range("D" & i).Value = "GBBRS" Or .Range("D" & i).Value = "GBLPL" Or .Range("D" & i).Value = "GBSOU" Then
.Range("A" & i & ":H" & i).Interior.ColorIndex = 35
ElseIf .Range("D" & i).Value = "FIHNO" Or .Range("D" & i).Value = "SEGOT" Then
.Range("A" & i & ":H" & i).Interior.ColorIndex = 36
ElseIf .Range("D" & i).Value = "ZADUR" Or .Range("D" & i).Value = "ZAELS" Or .Range("D" & i).Value = "ZAPLZ" Then
.Range("A" & i & ":H" & i).Interior.ColorIndex = 45
End If
Next i
End With