How to set a range using values from referenced cells? - excel

Question

I am trying to construct a macro to fill a certain number of blank cells after the end of my filled cells with zeros. This macro cycles through all of the sheets in the workbook (except the first sheet, which is named in the code). My code is below:
NumSh = ThisWorkbook.Worksheets.Count
For Each sh In ActiveWorkbook.Worksheets
First = LastRow(sh)
If IsError(Application.Match(sh.Name, _
Array("ECG_Log (root)"), 0)) Then
For i = 1 To (NumSh - 1)
LastVal = i + 4
Last = Worksheets("ECG_Log (root)").Cells(LastVal, 12).Value
'MsgBox (First)
Set ZerRng = sh.Range(Cells(First, 1), Cells(Last, 2))
'^^this is where is throws the 1004: range of object failed
'error
Range(ZerRng).Value = 0
Next i
End If
Next
End Sub
Function LastRow(sh As Worksheet)
On Error Resume Next
LastRow = sh.Cells.Find(What:="*", _
After:=sh.Range("A1"), _
Lookat:=xlPart, _
LookIn:=xlFormulas, _
SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious, _
MatchCase:=False).Row
On Error GoTo 0
End Function
Ideally, I would like to open each worksheet, find the last row ("First"), and define a range from that last row to the value ("Last") from a cell on the first sheet. It seems that the correct values are being found for First and Last, but I am still catching an error when trying to define my range for zeros. Any suggestions?

Answer 1

Fill zeros
Sub FillZeros()
Const cSheet As String = "ECG_Log (root)" ' Source Worksheet Name
Const cFer As Long = 4 ' Source Above First Row Number
Const cCol As Variant = 12 ' Source Column Letter/Number ("L")
Const cCols As String = "A:B" ' Target Columns Address
Dim ws As Worksheet ' Target Worksheet
Dim Fer As Long ' Target First Empty Row
Dim Lr As Long ' Target Last Row
Dim i As Long ' Source Row Counter
' Loop through worksheets in this workbook (workbook containing this code).
For Each ws In ThisWorkbook.Worksheets
' Check if name of current Target Worksheet is NOT equal to Source
' Worksheet Name.
If ws.Name <> cSheet Then
' Increase (count) Source Row.
i = i + 1
' Calculate current Target First Empty Row using LastRow function.
Fer = LastRow(ws) + 1
' Calculate Target Last Row i.e. retrieve value from cell at
' current row and Source Column of Source Worksheet.
Lr = ThisWorkbook.Worksheets(cSheet).Cells(i + cFer, cCol).Value
' In Current Target Columns
With ws.Columns(cCols)
' Prevent error if already done.
On Error Resume Next
' Calcutate Target Range.
' Write zeros to Target Range.
.Rows(Fer).Resize(Lr - Fer + 1) = 0
' Reset error.
On Error GoTo 0
End With
End If
Next
End Sub
Function LastRow(ws As Worksheet) As Long
On Error Resume Next
' The After argument's default parameter is the left upper cell of
' Expression (range) i.e. A1 in this case.
' The LookAt and MatchCase arguments are not important because of
' What:="*".
LastRow = ws.Cells.Find("*", , xlFormulas, , xlByRows, xlPrevious).Row
On Error GoTo 0
End Function