Set Rng comes up as Nothing - excel

Question

I would like some help on the below if you can.
I'm working between 2 workbooks and I want from the first one to find the value of Cell("B6") which happens to be a date on the second Workbook in column B. Although it seems that the code finds the date when it comes to set it as a range it comes as empty. Can you please help me to see what I'm doing wrong.
I'm a novice in VBA and I'm trying with an online search to make my life easier.
Thank you in advance.
Sub Update_Forecast_2()
Dim myFile As String
Dim YourFolderPath As Variant
Dim FindString As Date
Dim newFile As String
FindString = CLng(Date)
Dim Rng As Range
YourFolderPath = "C:\Users\konstand\Desktop\Forecast"
ChDir YourFolderPath
myFile = Application.GetOpenFilename
If myFile = "False" Then Exit Sub
Workbooks.Open Filename:=myFile
newFile = Replace(myFile, YourFolderPath + "\", "")
Range("B6").Select
Workbooks("Forecast file.xlsm").Activate
Sheets("Forecast_Sort").Activate
Range("A1").FormulaR1C1 = myFile
Workbooks(newFile).Activate
Range("B6").Activate
FindString = Workbooks(newFile).Sheets("Forecast").Range("B6").Value
'MsgBox FindString
If Trim(FindString) <> "" Then
With Workbooks("Forecast file").Sheets("Forecast_Sort").Range("B:B")
Set Rng = .Find(What:=DateValue(FindString), _
After:=.Cells(.Cells.Count), _
LookIn:=xlValues, _
LookAt:=xlWhole, _
SearchOrder:=xlByRows, _
SearchDirection:=xlNext, _
MatchCase:=False)
If Not Rng Is Nothing Then
Rng.Select
End If
Workbooks("Forecast file.xlsm").Activate
End With
End If
End Sub
Following Erjon's request in order to help you more to understand what I'm trying to do I attached 2 pictures and kind of explained something. I hope I helped and didn't make it more confusing.
So I have the main file on which I want to see the changes
Main File
Then I have the file from which I want to take the updated values every week if not more frequently. Be aware that this file every time will have a different name, such as "Wk09Update.xlsx", "Wk10Update.xlsx", "Wk11Update.xlsx", .......
Though before I go to the new file to copy and paste the new values I want on the main file from the date that the new file starts to copy the values from columns H,I, & J and paste them on top of the existing values in columns C, D, & E. Then I want to go to the new file and copy/paste the updated values from there to columns H,I, & J on the main file so I can see the diffenerces from a week to week update.
New File(Wk11Update.xlsx)
How it should be after Wk12Update
What I'm trying to do
Object Variable or With block Variable not set

Answer 1

First of all you need to make your code simple for example you have a lot of .Activate.
This will for sure in some point lead you into confusion.
you have to declare first all your worksheets and workbooks like this:
Sub Test()
dim book1 as workbook 'a workbook
dim book2 as workbook 'another workbook
dim SheetOfBook1 as worksheet
dim SheetOfBook2 as worksheet
set book1 = workbooks("NameOfWorkbook1.xlsm")
set book2 = workbooks("NameOfWorkbook2.xlsm")
set SheetOfBook1 = book1.worksheets("NameOfSheet")
set SheetOfBook2 = book2.worksheets("NameOfSheet")
'at this point you can check everything you want without activating something for example
SheetOfBook1.range("A1") = SheetOfBook2.Range("A1") 'or whatever
'if you want to check if a value in book1 exists in book2 then do a loop
dim cell as range
for each cell in SheetOfBook2.Range("A1:A100).Cells
If SheetOfBook1.range("A1") = Cell.Value Then
msgbox "I founded what you are searching for"
End If
Next Cell
End Sub
So you have to eliminate all this .activate, use loops etc. As for your example can you edit your question and can you illustrate with an image what you want to achieve?
Edit
If you want to open workbooks based on weeknumber i have this following code:
Sub Test()
Dim Main As Workbook
Dim Update As Workbook
Dim ForecastSort As Worksheet
Dim Forecast As Worksheet
Dim CheckIfOpen
Dim WeekNumber As String
Dim FirstDayInWeek
Dim FirstDayOfWeekRow As Long
Dim lRowUpdate As Long
Set Main = Workbooks("Main.xlsm")
Set ForecastSort = Main.Worksheets("Forecast_Sort")
'The code below will open the workbook which for name has the number week of today date automatically----------------------------------------------
WeekNumber = WorksheetFunction.WeekNum(Date) + 1 'The requested week
CheckIfOpen = IsWorkBookOpen("C:\Users\Erjon-PC\Desktop\Forecast\Wk" &
WeekNumber & "Update.xlsx") 'Checks if the update workbook is opened or not
FirstDayInWeek = Date - Weekday(Date, vbUseSystem) + 2 'First day of requested week
FirstDayOfWeekRow = ForecastSort.Range("B:B").Find(FirstDayInWeek).Row 'Finds the row of the start day of the requested week in main book
If CheckIfOpen = True Then
Set Update = Workbooks("Wk" & WeekNumber & "Update.xlsx")
Else
Set Update = Workbooks.Open("C:\Users\Erjon-PC\Desktop\Forecast\Wk" & WeekNumber & "Update.xlsx")
End If
'---------------------------------------------------------------------------------------------------------------------------------------------------
Set Forecast = Update.Worksheets("Forecast")
lRowUpdate = Forecast.Cells(Forecast.Rows.Count, "W").End(xlUp).Row 'Last row in column W in update book
Forecast.Range("W2:Y" & lRowUpdate).Copy
ForecastSort.Range("H" & FirstDayOfWeekRow).PasteSpecial xlPasteValues
Update.Close savechanges:=False
End Sub
Function IsWorkBookOpen(FileName As String)
Dim ff As Long, ErrNo As Long
On Error Resume Next
ff = FreeFile()
Open FileName For Input Lock Read As #ff
Close ff
ErrNo = Err
On Error GoTo 0
Select Case ErrNo
Case 0: IsWorkBookOpen = False
Case 70: IsWorkBookOpen = True
Case Else: Error ErrNo
End Select
End Function
The above code will open the workbook that has the week number in it's name, today it will open Wk11Update.xlsx, the next week it will open Wk12Update.xlsx.
If you want to open books that has for name future dates just add +1 or more to this code:
WeekNumber = WorksheetFunction.WeekNum(Date) + 1 'The requested week
Then in the opened book it will find last row with data in the column W, it will copy 3 column starting from W, and paste them in the column H of main book. The data will be pasted in the row where the first day of requested week is.