Select sepcific strings in different columns and print it AWK - search

Question

I have syntax :
awk -F'\t' '{for(i=1;i<=NF;i++) {if($i~/ensembl_gene_id*/) {h=$i}} ;for(a=1;a<=NF;a++) {if($a~/ensembl_gn*/) {z=$a}} print $1,$2,$3,z,h}'
This is syntax for search more strings in multiple unspecific fields separated by "\t" and print them. But my skills are not so good and I would like to rewrite it with only one loop (Now I have got two loops for "i" and "a"). Could you help me to get easier way with awk? (Code is working).
I think something like this :
awk -F'\t' '{for(i=1;i<=NF;i++) {if($i~/ensembl_gene_id* | esnembl_gn*/) {h=$i}} {print $1,$2,$3,h}'
But it prints only first match.
INPUT:
1 2 les ensembl_gene_id=aaa aha ensembl_gn=BRAF
2 3 pes ccds ensembl_gene_id=kkk ahl klkl ensembl_gn=OTC
2 2 ves ccds=1 ccds=2 ensembl_gene_id=cac ensembl_gn=BRCA
OUTPUT:
1 2 les ensembl_gene_id=aaa ensembl_gn=BRAF
2 3 pes ensembl_gene_id=kkk ensembl_gn=OTC
2 2 ves ensembl_gene_id=cac
Thank you

Answer 1

EDIT: After seeing OP's samples adding following solution.(change awk to awk 'BEGIN{FS=OFS="\t"} in case your Input_file is TAB delimited and your output should be in TAB delimited too.
awk '
match($0,/ensembl_gene_id[^ ]*/){
val=substr($0,RSTART,RLENGTH)
}
match($0,/ensembl_gn[^ ]*/){
val1=substr($0,RSTART,RLENGTH)
}
{
print $1,$2,$3,val,val1
val=val1=""
}
' Input_file
As far as I understood from your question(you want to run single for loop and check 2 conditions. if yes then we need not to use 2 loops rather we can use single loop with 2 conditions in it), could you please try following.
awk -F'\t' '{h=z="";for(i=1;i<=NF;i++){if($i~/ensembl_gene_id*/){h=$i};if($i~/ensembl_gn*/){z=$i}};print $1,$2,$3,z,h}' Input_file
OR(a non-one liner form of solution):
awk '
{
h=z=""
for(i=1;i<=NF;i++){
if($i~/ensembl_gene_id*/){
h=$i
}
if($i~/ensembl_gn*/){
z=$i
}
}
print $1,$2,$3,z,h
}
' Input_file
Issue with OP's attempt: It will always print 1 value only since in case other character's finding it will overwrite its previous value.

Answer 2

Are just trying to print the ensembl_gene_id and ensembl_gn fields? That'd be:
$ awk '{
delete f
for (i=1;i<=NF;i++) {
split($i,t,/=/)
f[t[1]] = $i
}
print $1, $2, $3, f["ensembl_gene_id"], f["ensembl_gn"]
}' file
1 2 les ensembl_gene_id=aaa ensembl_gn=BRAF
2 3 pes ensembl_gene_id=kkk ensembl_gn=OTC
2 2 ves ensembl_gene_id=cac ensembl_gn=BRCA