Change Number Generation Sequence - excel

Question

I am trying to write a VBA script where for every 5 counts of the number, the numbering starts back at 1. I'm taking the user input to loop through how many times the user wants to have the number set. Problem is, the numbers are not restarting from 1. Please help!!
Example: user enters 2 times, expected result is-
1
2
3
4
5
1
2
3
4
5
Code:
Dim myValue, myRows As Variant
Dim i, j, x, y, m, n, k As Integer
Sub Button1_Click()
'myValue = InputBox("Enter a starting number")
myRows = InputBox("Enter how times to repeat")
'Call repeat(myRows)
Call repeat2(myRows)
End Sub
Sub repeat2(rep1)
m = 0
n = 0
k = 1
For k = 1 To myRows
'k = k + 1
m = m + 5
n = n + 5
Call autogen2(k)
Next k
End Sub
Sub autogen2(z)
For k = 1 To m + 5
Range("F" & k).Select
ActiveCell.FormulaR1C1 = k
ActiveCell.Offset(1, 0).Select
Next k
End Sub

Answer 1

Your method seems overly complicated and loops through every cell instead of looping through groups of the target cells.
To simplify the math in calculating the target, I'd suggest Option Base 1 as a compiler directive in the code sheet's declarations area. This changes the default for an array from zero based to one based; i.e. from 0 to 4 to 1 to 5.
By using LBound and UBound, you can change the array without cahnging any of the other code that shapes the target.
Option Explicit
Option Base 1
Sub Button1_Click()
Dim myRows As Long, seq As Variant
'myValue = InputBox("Enter a starting number")
myRows = Application.InputBox(prompt:="Enter how times to repeat", Type:=xlNumbers)
If IsNumeric(myRows) Then
seq = Array(1, 2, 3, 4, 5)
autogen seq, myRows
End If
End Sub
Sub autogen(vals As Variant, n As Long)
Dim k As Long
For k = LBound(vals) To (n * UBound(vals)) Step UBound(vals)
Cells(1, "F").Offset(k - 1, 0).Resize(UBound(vals), 1) = _
Application.Transpose(vals)
Next k
End Sub

Answer 2

Number Generator (Fast)
Adjust the constants (Const) to fit your needs.
Option Explicit
Sub Button1_Click()
Dim myRows As Variant
myRows = InputBox("Enter how times to repeat")
If IsNumeric(myRows) Then
Repeat CLng(myRows)
End If
End Sub
Sub Repeat(Rows As Long)
Const cRange As String = "F1" ' First Cell Range Address
Const cStart As Long = 1 ' Starting Value
Const cEnd As Long = 5 ' Ending Value
Dim vntT As Variant ' Target Array
Dim i As Long ' Rows Counter
Dim k As Long ' Value Counter
Dim m As Long ' Target Array Row Counter
' Resize Target Array: Number of Values times Rows.
ReDim vntT(1 To (cEnd - cStart + 1) * Rows, 1 To 1)
' Loop through Rows.
For i = 1 To Rows
' Loop through Values.
For k = cStart To cEnd
' Count Target Array Row.
m = m + 1
' Write current Value to element in current Target Array Row.
vntT(m, 1) = k
Next
Next
With Range(cRange)
' Clear contents of Target Column Range from First Cell Range to
' bottom cell.
.Resize(.Worksheet.Rows.Count - .Row + 1).ClearContents
' Calculate Target Range: resize First Cell Range by Target Array Rows.
' Copy Target Array to Target Range.
.Resize(m) = vntT
End With
End Sub

Answer 3

One more:
Dim myRows As Long, tot As Long
myRows = Application.InputBox("Enter how times to repeat")
tot = myRows * 5
With ActiveSheet.Range("K1").Resize(tot, 1)
.FormulaArray = "=1+MOD(ROW(1:" & tot & ")-1,5)"
.Value = .Value
End With