Excel get multiple sub-strings from a string - excel

Question

I have got an Excel file with a column named Comments in a sheet called Resources (accessible as Resources[#Comments]), the data looks something similar to,
+=============================================+
| Comments |
+=============================================+
| [7/2] Level changed from 10 to 9 |
| [14/2] Alignment changed from ABC to XYZ |
| [21/2] Location changed from US to UK |
| [28/2] Chapter changed from [blank] to ABCD |
+---------------------------------------------+
| [14/2] Level changed from 5 to 4 |
| [21/2] Location changed from US to UK |
| [21/2] Chapter changed from JKLM to ABCD |
+---------------------------------------------+
| [28/2] Chapter changed from EFGH to MNOP |
+---------------------------------------------+
| [21/2] Location changed from IN to JP |
+---------------------------------------------+
The output I'm looking for should look something like (essentially extracting text between Chapter changed from <SOURCE> to <DESTINATION>),
+=============================================+==============+==============+
| Comments | Old Chapter | New Chapter |
+=============================================+==============+==============+
| [7/2] Level changed from 10 to 9 | [blank] | ABCD |
| [14/2] Alignment changed from ABC to XYZ | | |
| [21/2] Location changed from US to UK | | |
| [28/2] Chapter changed from [blank] to ABCD | | |
+---------------------------------------------+--------------+--------------+
| [14/2] Level changed from 5 to 4 | | |
| [21/2] Location changed from US to UK | | |
| [21/2] Chapter changed from JKLM to ABCD | | |
+---------------------------------------------+--------------+--------------+
| [28/2] Chapter changed from EFGH to MNOP | EFGH | MNOP |
+---------------------------------------------+--------------+--------------+
| [21/2] Location changed from IN to JP | | |
+---------------------------------------------+--------------+--------------+
Notes:
Cell might not have any "Chapter changed" text in which case no processing is required.
"Chapter changed" text is always the last line.
Only want to track the change if it was today (e.g. [28/2] =TEXT(today(), "dd/m")
I think Excel wraps text within "" (double quotes).
I am happy with either Excel formula or VBA script. Already tried stuff like KuTools, =MID(Resources[#Comments],SEARCH("Chapter changed from",Resources[#Comments])+20,SEARCH("to", Resources[#Comments]) - SEARCH("Chapter changed from",Resources[#Comments])-21).
To check the date part I am using, =IF(ISNUMBER(SEARCH("["&TEXT(TODAY(), "dd/m")&"] Chapter changed", Resources[#Comments])), "Yes", "")
Thanks.

Answer 1

It is pretty simple actually...
Spilt the cell contents using vbnewline or Chr(10)
Split on "["
Split on "]"
Check Date
Split on "from"
Split on "to"
Code: Is this what you are trying?
Sub Sample()
Dim cellValue As String
Dim tmpAr As Variant
Dim Dt As String, lastLine As String
Dim OLDc As String, NEWc As String
Dim rng As Range
'~~> Set the range
Set rng = Sheet1.Range("A2")
'~~> Split on Linefeed. It could be Chr(13) as well
tmpAr = Split(rng.Value, Chr(10))
'~~> Get the last line
lastLine = tmpAr(UBound(tmpAr))
'~~> Get the date part
Dt = Split(lastLine, "[")(1)
Dt = Split(Dt, "]")(0)
'~~> Check if it is same as today
If Format(Date, "D/M") = Dt Then
lastLine = Split(lastLine, "from")(1)
OLDc = Trim(Split(lastLine, "to")(0))
NEWc = Trim(Split(lastLine, "to")(1))
rng.Offset(, 1).Value = OLDc
rng.Offset(, 2).Value = NEWc
End If
End Sub

Answer 2

you could use Replace() method of Range object:
Sub DoThat()
Dim cell As Range
With Range("A1", Cells(Rows.Count, 1).End(xlUp))
.Offset(, 1).Resize(, 2).Value = .Value
For Each cell In .Offset(, 1).Cells
If InStr(cell.Value2, Format(Date, "D/M")) > 0 Then
cell.Replace "*from ", ""
cell.Replace " to *", ""
cell.Offset(, 1).Replace "*to ", ""
Else
cell.Resize(, 2).ClearContents
End If
Next
End With
End Sub