Formatting Multiple cells with letters and number in VBA - excel

Question

I have been trying to figure this problem out for some time to no avail.
I have a file that tracks different types of invoices. The invoices have both numbers and letters ex. ABC_1234_12345678. I want excel to format the invoice codes by adding the under scores after the user inputs the invoice code(without the underscores). I currently have a code that can do it for single cell but I was wondering how I could change it format a select number of cells ex. A1-A8. I will add my code in the comments.
Thank you for the help, I will be very thankful. :)
Private Sub Worksheet_Change(ByVal Target As Range)
Dim rngWatch As Range
Dim strOld As String
Dim strNew As String
'What cell is the invoice number in?
Set rngWatch = Range("A1")
'Did user change it?
If Intersect(rngWatch, Target) Is Nothing Then Exit Sub
strOld = rngWatch.Value
'Are there already hypens?
If Len(strOld) = Len(Replace(strOld, "_", "")) Then strNew = Left(strOld, 3) & "_" & Mid(strOld, 4, 3) & "_" & Mid(strOld, 8)
'Turn this off for the momenet
Application.EnableEvents = False
rngWatch.Value = strNew
Application.EnableEvents = True
End If
End Sub

Answer 1

Expand your rngWatch:
Private Sub Worksheet_Change(ByVal Target As Range)
Dim rngWatch As Range, r As Range
Dim strOld As String
Dim strNew As String
'What cell is the invoice number in?
Set rngWatch = Range("A:A")
'Did user change it?
If Intersect(rngWatch, Target) Is Nothing Then Exit Sub
For Each r In Intersect(Target, rngWatch)
strOld = r.Value
'Are there already hypens?
If Len(strOld) = Len(Replace(strOld, "_", "")) Then
strNew = Left(strOld, 3) & "_" & Mid(strOld, 4, 3) & "_" & Mid(strOld, 8)
'Turn this off for the momenet
Application.EnableEvents = False
r.Value = strNew
Application.EnableEvents = True
End If
Next r
End Sub
Note:
We use a loop in case the user changes several cells in column A simultaneously via Copy/Paste.

Answer 2

This can depend upon how you want the code to run. You could for example create a macro that processes all of the cells within a specific range once it has been run, which to me is a sensible way to do it. You could get the macro to process only the selected cells, which is another option. There are many ways to do this.
I have taken your example code and adjusted it so that any adjustments to cells within the _MyNamedRange named range are processed. Just incase you enter the same code into more than 1 cell, it scans through the intersect using a for loop, but you may want to get rid of this depending on how you see your worksheet functioning. You will need to create a named range _MyNamedRange, where the macro will function.
Private Sub Worksheet_Change(ByVal Target As Range)
Dim rngWatch As Range
Dim strOld As String
Dim strNew As String
Dim rngCell As Range, rngInter As Range
'What cell is the invoice number in?
Set rngWatch = Range("_MyNamedRange")
'Get intersect of the change
Set rngInter = Intersect(rngWatch, Target)
'Exit of the change does not intersect with the named range
If rngInter Is Nothing Then Exit Sub
'Scan through the intersect cells and adjust the cells
Application.EnableEvents = False
For Each rngCell In rngInter
strOld = rngCell.Value
'Are there already hypens?
strNew = ""
If Len(strOld) = Len(Replace(strOld, "_", "")) Then strNew = Left(strOld, 3) & "_" & Mid(strOld, 4, 3) & "_" & Mid(strOld, 8)
'Update the cell
rngCell.Value = strNew
Next rngCell
Application.EnableEvents = True
End Sub