Cassandra select distinct and order by cqlsh - cassandra

Question

I am new to Cassandra and to this forum. I' m executing Cassandra query using cqlsh but I don't know how to do execute a query like sql select distinct a, b, c from table order by d asc using Cassandra. How can I do? What would be the structure of the table?

Answer 1

Your primary key consists of partition keys and clustering columns.
DISTINCT queries must only request partition keys.
ORDER BY is supported on clustered columns.
Suppose we have a sample table like following,
CREATE TABLE Sample (
field1 text,
field2 text,
field3 text,
field4 text,
PRIMARY KEY ((field1, field2), field3));
DISTINCT requires all the parition keys to be passed comma separated.
So you can't run this query select distinct field1 from Sample;. A valid expression would be select distinct field1, field2 from Sample;.
It internally hits all the nodes in the cluster to find all the partition keys so if you have millions of partitions in you table, I would expect a performance drop with multiple nodes.
By default, records will be in ascending order for field3. Below query will provide records in descending order of field3.
select * from Sample where field1 = 'a' and field2 = 'b' order by field3 desc;
If you already know your query patterns and the way you would require data to be ordered, you can design the table in that way. Suppose you always require records in descending order for field3 , you could have designed your table in this way.
CREATE TABLE Sample (
field1 text,
field2 text,
field3 text,
field4 text,
PRIMARY KEY ((field1, field2), field3))
WITH CLUSTERING ORDER BY (field3 DESC);
Now querying without order by will result in the same result.
You can use order by with multiple clustered columns. But you can't skip the order. To understand that let's have a sample table like below,
CREATE TABLE Sample1 (
field1 text,
field2 text,
field3 text,
field4 int,
field5 int,
PRIMARY KEY ((field1, field2), field3, field4));
I added few dummy records.
You may use order by multiple columns like this select * from Sample1 where field1 = 'a' and field2 = 'b' order by field3 desc, field4 desc;
NOTE : All fields need to be either in positive order (field3 asc, field4 asc) or negative order (field3 desc, field4 desc). You can't do (field3 asc, field4 desc) or vice versa.
Above query will result in this.
By writing we can't skip the order in order by, I meant we cant do something like select * from Sample1 where field1 = 'a' and field2 = 'b' order by field4 desc;
I hope this helps !