Check if AddMember method has failed - excel

Question

I am writing code in VBA (in Excel) that puts Outlook contacts into a distribution list.
It works so far, but error handling in case the contact does not exist is not working. MS says
If the specified recipient is not valid, the AddMember method will
fail.
So how do you notice if the method fails?
Public Function olAddContactToList(ByVal sLastName As String, _
Optional ByVal sFirstName As String, _
Optional ByVal sGroup As String) As Boolean
Dim oOutlook As Object ' Outlook.Application
Dim oNameSpace As Object ' Outlook.NameSpace
Dim oMAPIFolder As Object ' Outlook.MAPIFolder
Dim oContact As Object ' Outlook.ContactItem
Dim oList As Object ' Outlook.DistListItem
Dim oMail As Object ' Outlook.MailItem
Dim oRecip As Object ' Outlook.Recipient
Const olFolderContacts = 10
On Error GoTo ErrHandler
Set oOutlook = CreateObject("Outlook.Application")
Set oNameSpace = oOutlook.GetNamespace("MAPI")
Set oMAPIFolder = oNameSpace.GetDefaultFolder(olFolderContacts)
Set oList = oNameSpace.GetDefaultFolder(olFolderContacts).Items(sGroup)
'Adds a member to a new distribution list
Set oMail = oOutlook.CreateItem(olMailItem)
'Create recipient for distlist
Set oRecip = oOutlook.Session.CreateRecipient(sFirstName & " " & sLastName)
oRecip.Resolve
oList.AddMember oRecip
oList.Save
olAddContactToList = True
ErrHandler:
If Err.Number <> 0 Then
MsgBox "Fehler beim Hinzufügen des Outlook-Kontakts zu einer Liste." & vbCrLf & _
CStr(Err.Number) & " " & Err.Description, vbExclamation + vbOKOnly
olAddContactToList = False
End If
Set oContact = Nothing
Set oMAPIFolder = Nothing
Set oNameSpace = Nothing
Set oOutlook = Nothing
Set oList = Nothing
Set oMail = Nothing
Set oRecip = Nothing
End Function
I have tried
Dim AddCheck As Long
AddCheck = oList.AddMember(oRecip)
but AddCheck stays 0 irrespective of the contact existing and being successfully added to the list or not existing and failing to be added.

Answer 1

As the result of Recipient.Resolve is either True or False (says Microsoft), you should check that.
Otherwise you only have a firstname and lastname, but not a full email address:
If Not oRecip.Resolve Then
' no resulting email address
Else
' email address found, go further
End If
As DistListItem.AddMember even raises no error, if you try to add a simple phone number string (just doesn't add it), I suggest to compare DistListItem.MemberCount (oList.MemberCount in your code) additionally before and after trying to add a new member.
By that you`ll either get an error or an unchanged member count, if something went wrong, and can do further checks.