Finding value where variable changes - excel-formula

Question

I am creating an excel worksheet to summarise values in another worksheet. The problem is that I have many different customer ID's and every six month period we receive a summary of their activities on their phone. One column shows whether they have updated to the new OS. It shows a 0 if they haven't and a 1 if they have done it in that 6 month period or prior to that six month period.
I have already tried playing around with IFERROR and INDEX formulas, but these haven't worked for me.
I really haven't been able to get this to work at all, so I don't have any code to show you. However this is the general format of the data.
In column A you have all the customer ID's and there are multiple entries for each 6 month period. Then in column B you have the date of the 6 month entry, and in Column C a 0 or 1 according to if they haven't or have updated yet respectively.
+-------------+--------+----------+
| Customer ID | Date | Updated? |
+-------------+--------+----------+
| 001 | Dec-17 | 0 |
| 001 | Jun-17 | 0 |
| 001 | Dec-16 | 0 |
| 001 | Jun-16 | 0 |
| 002 | Dec-17 | 1 |
| 002 | Jun-17 | 1 |
| 002 | Dec-16 | 0 |
| 003 | Dec-17 | 1 |
| 003 | Jun-17 | 1 |
| 003 | Dec-16 | 1 |
| 003 | Jun-16 | 0 |
| 003 | Dec-15 | 0 |
+-------------+--------+----------+
The output should be in a separate tab which only has the unique Customer IDs and look like this:
+-------------+--------------+
| Customer ID | Date Updated |
+-------------+--------------+
| 001 | 0 |
| 002 | Jun-17 |
| 003 | Dec-16 |
+-------------+--------------+
I think it will require array formulas, but don't really know how these work.
Any help would be greatly appreciated.

Answer 1

Assuming that the dates are real dates, not text:
If you have Office 365 you can use Minifs
=MINIFS(Table1[month],Table1[id],F5,Table1[value],1)
If you don't have that function, you can use this array formula:
=MIN(IF((Table1[id]=F5)*(Table1[value]=1),Table1[month]))
Remember to confirm with Ctrl+Shift+Enter.
Format the result with custom format mmm-yy;;0 which shows 0 for 0 values, not dates.
Adjust the formulas accordingly, if you want to place them on a different sheet.
Edit after comment: The formulas I posted use structured referencing to the Excel Table. If your data is not in a Table Object or you don't want to use structured references, you can use regular references, of course.
=MINIFS($C$5:$C$16,$B$5:$B$16,F5,$D$5:$D$16,1)
or
=MIN(IF(($B$5:$B$16=F5)*($D$5:$D$16=1),$C$5:$C$16))