Groovy : datetime delta and JsonOutput.toJson - groovy

Question

I'm trying to return some data from the database. When I call the method JsonOutput.toJson() with the provided data, it automatically changes the delta of my datatime.
This is my code :
def result = groovy.json.JsonOutput.toJson(data)
println(data)
println(result)
response.setContentType("application/json");
The first prints the following:
[[ DateStart:2019-01-14 09:34:51.0, DateEnd:2019-01-14 10:27:22.68]]
And the second after the json formatting show another date (hours - 1) :
[{"DateStart":"2019-01-14T08:34:51+0000","DateEnd":"2019-01-14T09:27:22+0000"}]
Any tips to format to JSON without changing any date/delta?

Answer 1

Based on the data.toString() output format:
[[ DateStart:2019-01-14 09:34:51.0, DateEnd:2019-01-14 10:27:22.68]]
it looks like you are dealing with JSON serialization of thejava.sql.Timestamp type. If you want to prevent the default timestamp serializer from being used, you will have to format timestamps manually before JSON serialization happens.
Consider the following example:
import groovy.json.JsonOutput
import java.sql.Timestamp
def format = "yyyy-MM-dd'T'hh:mm:ss.S"
def date = new Date().parse(format, "2019-01-14T09:34:51.0")
def dateStart = new Timestamp(date.time)
def dateEnd = new Timestamp((date + 20).time)
def data = [[DateStart: dateStart, DateEnd: dateEnd]]
println "Raw data:"
println data
println "\nJSON without formatting:"
println JsonOutput.toJson(data)
data = data.collect { el -> el.collectEntries { k,v ->
def value = v instanceof Timestamp ? v.format(format) : v
return [(k): value]
}}
println "\nJSON after formatting:"
println JsonOutput.toJson(data)
The output:
Raw data:
[[DateStart:2019-01-14 09:34:51.0, DateEnd:2019-02-03 09:34:51.0]]
JSON without formatting:
[{"DateStart":"2019-01-14T08:34:51+0000","DateEnd":"2019-02-03T08:34:51+0000"}]
JSON after formatting:
[{"DateStart":"2019-01-14T09:34:51.0","DateEnd":"2019-02-03T09:34:51.0"}]
The most important part (formatting timestamp value to its string representation) happens in the following part:
data = data.collect { el -> el.collectEntries { k,v ->
def value = v instanceof Timestamp ? v.format(format) : v
return [(k): value]
}}
It assumes that your list of maps may contain other key-value pairs which don't hold the timestamp value. If we deal with a timestamp, we format it using yyyy-MM-dd'T'hh:mm:ss.S format, and we return a not-modified value otherwise.