How to search for a string in a saved emails folder - excel

Question

We are in the middle of a new production line start-up and have a lot of info and emails to communicate. What we want is that all the info is gathered in a folder on the server and that people who need info could search in a textfield to find related subjects. So what I want is to search for a string in email body's but currently I only know how to do this in my own mail box but not how to do it in saved emails in a folder. The code that I have for now is this and is for a Excel macro:
Sub FindSubjectInEmails()
Dim outlookApp
Dim olNs As Outlook.Namespace
Dim Fldr As Outlook.MAPIFolder
Dim olMail As Variant
Dim myTasks
Dim sir() As String
Set outlookApp = CreateObject("Outlook.Application")
Set olNs = outlookApp.GetNamespace("MAPI")
Set Fldr = olNs.GetDefaultFolder(olFolderInbox)
Set myTasks = Fldr.Items
For Each olMail In myTasks
If (InStr(1, olMail.Body, "text_to_find", vbTextCompare) > 0) Then
olMail.Display
Exit For
End If
Next
End Sub

Answer 1

Is this what you are trying?
Option Explicit
Sub Sample()
Dim OutApp As Object, OutMsg As Object
Dim msgFolder As String, emlFile As String
Set OutApp = CreateObject("Outlook.Application")
'~~> Change this to the relevant folder
msgFolder = "C:\Users\routs\Desktop\Test\"
emlFile = Dir(msgFolder & "\*.msg")
'~~> Loop through the folder to work with the emails
Do While Len(emlFile) > 0
Set OutMsg = OutApp.Session.OpenSharedItem(msgFolder & emlFile)
If (InStr(1, OutMsg.Body, "text_to_find", vbTextCompare) > 0) Then
OutMsg.Display
Exit Do
End If
emlFile = Dir
Loop
Set OutMsg = Nothing
Set OutApp = Nothing
End Sub