Crash when deleting cell values Worksheet_Change event - excel

Question

I would like to run a macro (say test1) continously on a worksheet whenever the value in a given range (F5 to LastRow). The Worksheet_Activate and Worksheet_Change event helped in this respect. However, Excel crashes whenever the values in the range are deleted. As example:
F5 = 100, F6 = 120,F7 = 140
Suppose the value of F5 is changed to 120. Then the macro and events are working fine. However, when all the values are deleted (so F5 uptill F7 are empty), Excel crashes.
I have tried to run each line in my code seperately, but I am not sure what is causing the crash (perhaps the loop as written in the macro)?
I am a beginner with VBA and any assistance is much appreciated :-)
Sub TEST()
Dim LastRow As Long
Dim i As Long
LastRow = Sheets("blad1").Range("F5").End(xlDown).Row
For i = 5 To LastRow
Range("Z" & i).Formula = "=ABS(F" & i & " -(J" & i & " *(100/21)))< 5"
'Checks if the value in column F matches the amount in column J for each
'cellin that column with a significance of 5. The return is shown as
'True or False.
Next i
For i = 5 To LastRow
If Range("Z" & i) = True Then Range("F" & i).Interior.Color = RGB(255,
255, 255) Else: Range("F" & i).Interior.Color = RGB(255, 0, 0)
'If the
'value in column Z is True, then the cell colour in column F is white.
'If False, then red.
Next i
End Sub
'These are the lines on the relevant worksheet:
Private Sub Worksheet_Activate()
Call test
End Sub
Private Sub Worksheet_Change(ByVal Target As Range)
Dim LastRow As Long
LastRow = Sheets("Test").Range("F5").End(xlDown).Row
If Not Intersect(Target, Me.Range("F5:F" & LastRow)) Is Nothing Then
Application.EnableEvents = False
Call test
Application.EnableEvents = True
End If
End Sub

Answer 1

The line
LastRow = Sheets("blad1").Range("F5").End(xlDown).Row
is returning a value equal to the absolute very last row possible (1048576) when column F is empty. The rest of your macro is then iterating through the entire sheet executing your code for every single row. You can imagine what happens when you try to insert 1048572 formulas into a spreadsheet. A better option would be to use
LastRow = Sheets("blad1").Range("F" & Rows.Count).End(xlUp).Row
To get the last used row searching from the bottom up. Then you could change your Worksheet_Change logic to
If LastRow > 1 Then
'Code Here
End if
EDIT:
Also worth noting, when LastRow = Sheets("blad1").Range("F5").End(xlDown).Row then this code
If Not Intersect(Target, Me.Range("F5:F" & LastRow)) Is Nothing Then
Application.EnableEvents = False
Call test
Application.EnableEvents = True
End If
will always evaluate True when you're editing values in Column F at any row number greater than row 4 because Intersect() basically says "If Range one and Range two overlap return true". So, Range("F7") is within Range("F5:F1048576") regardless of whether or not it has a value.