VBA multiple For loops - works right only first two times - excel

Question

So I have been working on this little piece of code for a couple of days now and have hit a snag that I just cannot figure out. Basically I have a nested for loop that is supposed to take values from one Sheet and put them in a data sheet so that those value can be saved and averaged out over time.
I want the data from the cells M5 - M35 to get put into the data sheet like this: from left to right A3 - AC200, but I also want the loop to stop once the M5 - M35 range runs out of values and when the user next pushes the button to store data I want the loop to start on the next line down.
So This Spreadsheet is for my work, it is for a Butchery Yield Test and I want it to have it's owned database stored on a hidden sheet that will be averaged out over time so I or others can come back to it and update it every few months to make the averages more accurate and to get a better understanding of the profitability of certain cuts of meat.
I have tried setting the loop values back to their starting values once the loop has filled out all the data which worked and I thought I'd solved the issue until I ran the test multiple time and found that the first and second time work as expected from the third onwards however it doesn't start the loop down at the next row it just continues through the range
Sub subData1()
Dim rng As Range
Dim rcell As Range
Dim ws As Worksheet
Dim Tws As Worksheet
Set Tws = Worksheets("Test")
Set ws = Worksheets("data")
For i = 3 To 200 'range is from cell A3 - A200
'if start cell already has value go down a row
If ws.Cells(i, 1).Value <> "" Then
i = i + 1
End If
'set the range for data sheet
Set rng = ws.Range(ws.Cells(i, 1), ws.Cells(i, 30).End(xlToRight))
For f = 5 To 35
For Each rcell In rng 'loop through each cell in data sheet range
If rcell.Value = "" Then 'if cell is blank input data
If Tws.Cells(f, 13).Value <> "" Then
'Check the selected Cell has a value
rcell.Value = Tws.Cells(f, 13).Value
f = f + 1
End If
Else
If f > 5 Then
MsgBox "Data Storage Updated", , "Data Storage"
f = 5
Exit Sub
'Else
'MsgBox "Value Must Be Greater Than Zero", , f
'f = 5
'Exit Sub
End If
End If
Next
Next
Next
End Sub

Answer 1

The reason it's working the first and second time is because of this line
If ws.Cells(i, 1).Value <> "" Then
i = i + 1
End If
But, if you'll notice, it's only running once for each iteration. Which means that on a blank sheet, it will evaluate false on the first iteration of the first run and continue, on the first iteration of the second run, it will evaluate true and move down one row to row 4, but on the first iteration of the third run it will also evaluate true and move down to row 4 and then place data starting at ws.Range(ws.Cells(i, 1), ws.Cells(i, 30).End(xlToRight))
You need to change your If-End If to a function that will retrieve the last used row in Column A of your data sheet. Additionally, you probably don't need your outer For-Next loop since that's looping through your output sheet and would output the same M5:M35 values for every single row.
If I understand your needs correctly, I believe you could utilize this to accomplish what you're looking for
Dim rng As Range
Dim ws As Worksheet
Dim Tws As Worksheet
Dim endRow As Long
Set Tws = Worksheets("Test")
Set ws = Worksheets("data")
endRow = ws.Range("A" & Rows.Count).End(xlUp).Row + 1
Set rng = ws.Cells(endRow, 1)
For f = 5 To 35
If Tws.Cells(f, 13).Value <> "" Then
rng.Value = Tws.Cells(f, 13).Value
Set rng = rng.Offset(0, 1)
End If
Next
With this, every sequential button click would insert data at a new row, looping through Tws.Cells(f,13) and placing that value in the right-most column by incrementally setting the range.