New to VBA and I'm trying to create a function - excel

Question

I'm attempting to make a user-defined function that mimics my formula. I need something more efficient than my formula.
I've tried VBA and using the above formula as is. This is ineffective for the larger datasets I'm working with.
=IF((AND(B2>=65,A2>=7)),"Greenbox",IF((AND(B2>10,A2=0,B2= "")),"Balance",IF((AND(B2>=65,A2<3)),"Yellowbox",IF((AND(B2<65,A2>=7)),"Purplebox",IF((AND(B2<65,A2<=3,A2>=1)),"Orangebox",IF(AND(B2>=65,A2<7,A2>=3),"Bluebox",IF(AND(A2<7,A2>=3,B2<65),"Redbox")))))))
A VBA function that mimics the formula.

Answer 1

If you do not want to supply an input to the UDF, you can grab the row number and worksheet using Application.Caller. Otherwise, you can add two arguments for the A2 & B2 range and compare the value there.
I have made no performance tests regarding the two methods, but I would imagine the one that does not use Application.Caller would be the one that has greater performance - but I figured another example wouldn't hurt.
Application.Caller Method
Function myFunc() As String
Dim r As Long, ws As Worksheet
Set ws = Application.Caller.Worksheet
r = Application.Caller.Row
If ws.Cells(r, "B").Value >= 65 And ws.Cells(r, "A").Value >= 7 Then
myFunc = "Greenbox"
ElseIf ws.Cells(r, "B").Value > 10 And ws.Cells(r, "A").Value = 0 Then
myFunc = "Balance"
'.... Continue
End If
End Function
Which the worksheet formula would look like: =myFunc(). (no arguments needed)
Function with Arguments Method
Function myFunc(rngA As Range, rngB As Range) As String
If rngB.Value >= 65 And rngA.Value >= 7 Then
myFunc = "Greenbox"
ElseIf rngB.Value > 10 And rngA.Value = 0 Then
myFunc = "Balance"
'.... Continue
End If
End Function
Which the worksheet formula would look like: =myFunc($A2, $B2).
As already mentioned in the comments by Scott Craner, AND(B2>10,A2=0,B2= "") isn't logically correct. B2>10 and B2="" will never be True when used together with AND, so you may need to figure your intentions out with that one.

Answer 2

Here's a go. Total is the value returned in the cell with the function called.
It would be cell a2 and B would be cell b2 in the example
=caseTest(A2,B2)
Per Scott's note, <10 is used rather than null. Feel free to edit.
There is also a default value if none of the conditions are met. Happy coding.
Function caseTest(A, B)
Dim scoreA As Integer, scoreB As Integer, result As String
scoreA = A.Value
scoreB = B.Value
If ((scoreA >= 7) And (scoreB >= 65)) Then
Total = "Greenbox"
ElseIf ((scoreA = 0) And (scoreB <10)) Then
Total = "Balance"
ElseIf ((scoreA < 3) And (scoreB >= 65)) Then
Total = "Yellowbox"
ElseIf ((scoreA >= 7) And (scoreB < 65)) Then
Total = "Purplebox"
ElseIf ((scoreA <= 3) And (scoreA >= 1) And (scoreB < 65)) Then
Total = "Orangebox"
ElseIf ((scoreA >= 3) And (scoreA < 7) And (scoreB >= 65))) Then
Total = "Bluebox"
ElseIf ((scoreA >= 3) And (scoreA < 7) And (scoreB < 65))) Then
Total = "Redbox"
Else
Total = "default"
End If
caseTest = Total
End Function

Answer 3

if you need help on creating custom functions below link is an useful guide
https://support.office.com/en-us/article/create-custom-functions-in-excel-2f06c10b-3622-40d6-a1b2-b6748ae8231f.
To answer your question, I have created a custom function based on what I deciphered from your formula.
Function Cust_SetBox(A as Range, B as Range) As String
'function will receive two parameters A and B as ranges and return back a string
Application.Volatile 'this ensures that formula will update when cell values are modified
'Original formula
'=IF((AND(B2>=65,A2>=7)),"Greenbox",IF((AND(B2>10,A2=0,B2= "")),"Balance",IF((AND(B2>=65,A2<3)),"Yellowbox",IF((AND(B2<65,A2>=7)),"Purplebox",IF((AND(B2<65,A2<=3,A2>=1)),"Orangebox",
'IF(AND(B2>=65,A2<7,A2>=3),"Bluebox",IF(AND(A2<7,A2>=3,B2<65),"Redbox")))))))
'adding .value="" condition as emtpy cells will show up as true while checking for X.Value<n
If B.Value = "" And A.Value = "" Then
Cust_SetBox = "Unknown"
ElseIf (B.Value = "" Or B.Value > 10) And A.Value = 0 Then 'you might want to check this condition as it is not clear from your formula
Cust_SetBox = "Balance"
ElseIf B.Value >= 65 And B.Value <> "" Then
If A.Value >= 7 Then
Cust_SetBox = "Greenbox"
ElseIf A.Value < 3 Then
Cust_SetBox = "Yellowbox"
ElseIf A.Value < 7 And A.Value >= 3 Then
Cust_SetBox = "Bluebox"
End If
ElseIf B.Value < 65 And B.Value <> "" Then
If A.Value >= 7 Then
Cust_SetBox = "Purplebox"
ElseIf A.Value <= 3 And A.Value >= 1 Then
Cust_SetBox = "Orangebox"
ElseIf A.Value < 7 And A.Value >= 3 Then
Cust_SetBox = "Redbox"
End If
Else
Cust_SetBox = "Unknown"
End If
End Function
To quickly add this function to your workbook.
use Alt+F11, insert a new module and add above code to the module. You should be able to use this new function as a formula.
Go to any cell and type the below
=Cust_SetBox(A1,B1)
The cell will show the value based on the logic above. Detailed explanation in the link above.
Note
Make sure Calculation is set to automatically calculate (in Formulas menu -> Calculation options) else press F9 to calculate
The workbook has to be saved as a macro enabled file else the function will not be available later.