How to create error message if column contains non-numeric field - VBA - excel

Question

I am trying to write a code to produce an error message if the values of the table are non-numeric. I am not getting any error messages but the code isn't accomplishing the task. Any help? Code below:
Sub Refresh()
'
' Warning Code to check if all values are numeric
'-----------------------------------------------------------------------
Dim sh As Worksheet
Dim i As Integer
Dim bisnumberic As Boolean
bIsNumeric = True
For Each sh In ActiveWorkbook.Sheets
Select Case sh.Name
Case "AltA", "AltB", "AltC1", "AltC2"
Dim lRow As Long
lRow = Cells(Rows.Count, 1).End(xlUp).Row
For i = 3 To lRow
If Not IsNumeric(Cells(i, 1).Value) Then
bisnumber = False
End If
Next i
End Select
Next sh
If bIsNumeric = False Then
'There are non-numeric values in your range
MsgBox "There are non-numeric values in your range. Go check-
yourself and try again."
Else
'-----------------------------------------------------------------------
' Code to summarize data Sheets("AlternativeSummary").Select
Range("B5").Select
ActiveSheet.PivotTables("PivotTable5").PivotCache.Refresh
MsgBox "Complete"
'All values in your range are numeric
End If
End Sub

Answer 1

lRow = Cells(Rows.Count, 1).End(xlUp).Row should have a clearly defined parent worksheet. Remember that you are cycling through a series of worksheets. Same with If Not IsNumeric(Cells(i, 1).Value) Then.
Sub Refresh()
'
' Warning Code to check if all values are numeric
'-----------------------------------------------------------------------
Dim sh As Worksheet, i As Long, bIsNumeric As Boolean, lRow As Long, errng as range
bIsNumeric = True
For Each sh In ActiveWorkbook.Worksheets
Select Case sh.Name
Case "AltA", "AltB", "AltC1", "AltC2"
lRow = sh.Cells(sh.Rows.Count, 1).End(xlUp).Row
For i = 3 To lRow
If Not IsNumeric(sh.Cells(i, 1).Value) Then
bIsNumeric = False
set errng = sh.Cells(i, 1)
Exit For
End If
Next i
End Select
If Not bIsNumeric Then Exit For
Next sh
If Not bIsNumeric Then
'There are non-numeric values in your range
MsgBox "There are non-numeric values in your range. Go check yourself and try again." _
& chr(10) & errng.address(0, 0, external:=true)
Else
'---------------------------------------------------
' Code to summarize data
With Sheets("AlternativeSummary")
.Activate
.Range("B5").Select
.PivotTables("PivotTable5").PivotCache.Refresh
MsgBox "Complete"
'All values in your range are numeric
end with
End If
End Sub

Answer 2

The problem here is in your if statement:
If Not IsNumeric(Cells(i, 1).Value) Then
bisnumber = False
End If
You are changing the bisnumber variable.
Later on, you actually check the bIsNumeric variable to see if something is or is not a number. You would need to change:
If Not IsNumeric(Cells(i, 1).Value) Then
bisnumber = False
End If
to:
If Not IsNumeric(Cells(i, 1).Value) Then
bIsNumeric = False
End If
Good code writing - and welcome to Stack Overflow.

Answer 3

Option Explicit
Sub Refresh()
'
' Warning Code to check if all values are numeric
'-----------------------------------------------------------------------
Dim sh As Worksheet
Dim i As Integer
Dim bIsNumeric As Boolean
bIsNumeric = True
For Each sh In ActiveWorkbook.Sheets
Dim lRow As Long
lRow = sh.Cells(Rows.Count, 1).End(xlUp).Row
For i = 3 To lRow + 1
If Not IsNumeric(sh.Cells(i, 1).Value) Then
bIsNumeric = False
End If
Next i
Next sh
If bIsNumeric = False Then 'There are non-numeric values in your range
MsgBox "There are non-numeric values in your range. Go check-yourself and try again."
Else
'-----------------------------------------------------------------------
' Code to summarize data Sheets("AlternativeSummary").Select
Range("B5").Select
ActiveSheet.PivotTables("PivotTable5").PivotCache.Refresh
MsgBox "Complete"
'All values in your range are numeric
End If
End Sub
This will loop through all the sheets and check for non-numeric fields.