Problem in reversing a string in assembly 8086 - string

Question

I need to reverse a given string in assembly 8086. I wrote a code that should work but I get the output
'MAGSM$HIMI
instead of
MAGSHIMIM
I can't figure out what is the problem with the code. I suspect the "$" is causing the problem but I have no idea.
My code:
org 100h
jmp main
chrs db 'M','I','M','I','H','S','G','A','M', '$'
main:
mov bp, sp
mov ax,offset chrs
call print_ax_str
mov ax, offset chrs
push ax
push 9
call reverse
PRINTN ;new line
mov ax,offset chrs
call print_ax_str
jmp stop
reverse proc
; First save the old BP
push bp
; Now establish new BP
mov bp, sp
;make space for 2 local variables
sub sp, 4
mov dx, [bp+6]
mov bx, [bp+4] ;bx = 9
dec bx ;bx = 8
add dx, bx ; dx = dx + 8
mov di, dx
mov SI, [bp+6]
mov cx, 4
L1:
mov dx, [si]
xchg ax, [di]
mov [si], ax
mov [di], dx
inc si ;si--
dec di ;di++
loop L1
mov sp, bp
; Restore OLD BP
pop bp
retn 4
reverse endp
stop:
mov ah, 0
int 16h
ret
include magshimim.inc

Answer 1

chrs db 'M','I','M','I','H','S','G','A','M', '$'
...
L1:
mov dx, [si]
xchg ax, [di]
mov [si], ax
mov [di], dx
inc si ;si--
dec di ;di++
loop L1
The biggest problem here is that your chrs string contains bytes but your reversing procedure works with words (2 bytes).
Looking at this loop I suspect that you've mixed 2 solutions to the reversing problem. The xchg ax, [di] instruction tells this.
Solution 1 using MOV
L1:
mov dl, [si]
mov al, [di]
mov [si], al
mov [di], dl
inc si ;si++
dec di ;di--
loop L1
Solution 2 using XCHG
L1:
mov dl, [si]
xchg dl, [di]
mov [si], dl
inc si ;si++
dec di ;di--
loop L1
Please notice that the comments in your code were wrong. Incrementing SI corresponds to "si++". Similarly decrementing DI corresponds to "di--".
Since you pass the length of the string to the procedure and have the pointers based on it, you should also base your loop counter on it and not use a fixed count of 4 via mov cx, 4.
mov cx, [bp+4] ;SLen
shr cx, 1 ;SLen/2
L1:
With some additional clean-up:
reverse proc
push bp
mov bp, sp
mov cx, [bp+4] ;SLen
mov si, [bp+6]
mov di, si
add di, cx
dec di
shr cx, 1 ;SLen/2
L1:
mov dl, [si]
mov al, [di]
mov [si], al
mov [di], dl
inc si ;si++
dec di ;di--
loop L1
pop bp
retn 4
reverse endp