Hide rows if no text on export to PDF - excel

Question

I have a simple script for exporting a range to Excel:
`Private Sub CommandButton2_Click()
With Sheets("Summary").Range("B2:H83")
.ExportAsFixedFormat _
Type:=xlTypePDF, _
Filename:="F:\Export.pdf", _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=True
End With
End Sub
`
The issue is that certain rows may or may not be populated based on inputs in separate sheets. So for example Rows 34-42 could be populated, but more likely than not only Row 34 is populated. This leaves a lot of white space in the exported PDF.
I have no idea how to structure my code to check if there is info in the Row, and if not then to hide the row thereby eliminating white space

Answer 1

I have adjusted your script to hide blank rows. It checks only the range you mention above, in case it's a dynamic range you can let me know.
Private Sub CommandButton2_Click()
Dim rowCounter As Integer
Dim columnCounter As Integer
Dim blankFlag As Boolean
With sheets("Summary")
'hide blank rows in 34-42 and 44-56 interval
For rowCounter = 34 To 56
blankFlag = True
For columnCounter = 2 To 8
If .Cells(rowCounter, columnCounter) <> "" Then
blankFlag = False
Exit For
End If
Next columnCounter
If blankFlag = True Then rows(rowCounter).EntireRow.Hidden = True
If rowCounter = 42 then rowCounter = rowCounter + 1
Next rowCounter
End With
With sheets("Summary").Range("B2:H83")
'export to PDF
.ExportAsFixedFormat _
Type:=xlTypePDF, _
filename:="F:\Export.pdf", _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=True
End With
End Sub

Answer 2

Better to hide all of the empty rows at once instead of hiding them individually on each iteration of the loop.
Private Sub CommandButton2_Click()
Dim mainRng As Range
Set mainRng = sheets("Summary").Range("B2:H83")
Dim unionRng As Range
Dim roww As Range
For Each roww In mainRng.rows
If WorksheetFunction.CountA(roww) = 0 Then
If Not unionRng Is Nothing Then
Set unionRng = Union(unionRng, roww)
Else
Set unionRng = roww
End If
End If
Next
If Not unionRng Is Nothing Then unionRng.EntireRow.Hidden = True
mainRng.ExportAsFixedFormat _
Type:=xlTypePDF, _
filename:="F:\Export.pdf", _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=True
If Not unionRng Is Nothing Then unionRng.EntireRow.Hidden = False
End Sub

Answer 3

I think you can try this code:
Private Sub CommandButton2_Click()
Dim ShtSummary As Worksheet
Dim i As Integer
Set ShtSummary = Sheets("Summary")
For i = 3 To 83
If Application.WorksheetFunction.CountA(Rows(i)) = 0 Then
ShtSummary.Rows(i).EntireRow.Hidden = True
End If
Next i
With Sheets("Summary").Range("B2:H83")
.ExportAsFixedFormat _
Type:=xlTypePDF, _
Filename:="F:\Export.pdf", _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=True
End With
End Sub
Good Luck.