Loop Through List and Generate Reports - excel

Question

I'm struggling with what I believe is a loop problem. I'm more of a "backyard mechanic" with Excel VBA so please excuse my simple question.
I can't share the workbook due to proprietary information unfortunately but I have the code I use with some field name changes.
Background: I have a column that I take 1 cell at a time and feed it into a pivot table field and run reports. The way I have it now, I delete the current Row which returns the reference back to cell A2. Think of it like a programming Pez dispenser. Awful and very brute force I know. The row delete operation takes a lot of system resources and I'd like to optimize it. I've tried reading through here and a few other websites for the past couple hours but I can't make heads or tails of what I'm coming across.
Any help would be very greatly appreciated!
Sub AutoReport()
Dim strPage As String
Worksheets("HomePage").Select
Beginning:
'Sets the name in Home Page to the name in Feederlist cell F2
With Sheet1
strPage = Worksheets("FeederList").Range("A2")
Worksheets("HomePage").PivotTables("PivotTable1").PivotFields("UNIQUE ID"). _
CurrentPage = strPage
End With
**Do a Bunch of Stuff**
' Feeds the next input into the machine
MoveToNext:
Worksheets("FeederList").Activate
Worksheets("FeederList").Range("A2").EntireRow.Delete
If Worksheets("FeederList").Range("A2") = "" Then
MsgBox "All Reports have been created.", vbInformation + vbOKOnly
Exit Sub
Else
GoTo Beginning
End If
End Sub

Answer 1

the acceptance is the first step to learning. In general, the stackoverflow community encourages to invigorate the technical and logical parts of the brain by providing the hints to solution and not the exact solution. However, as you are very new, I am starting with giving off hints and later on the code to rectify your issue. You are going very well with your code, however some minor tweaks will optimize your code significantly.
Worksheets("HomePage").Select
Dim lstRow As Long
Dim rngCell As Range
Dim rngSelection As Range
'Let's find the last row with data in column A.
'So that we only traverse the required range without the need of
'deleting previous cells while using the For loop.
lstRow = Worksheets("FeederList").Range("A" & Application.Rows.Count).End(xlUp).Row
Set rngSelection = Worksheets("FeederList").Range("A2:A" & lstRow)
For Each rngCell In rngSelection.Cells
'Ignore all the cells with blank value or else the pivot table will throw the error
If Trim(rngCell.Value) <> vbNullString Then
'Sets the name in Home Page to the name in Feederlist cell F2
strPage = rngCell.Value
Worksheets("HomePage").PivotTables("PivotTable1").PivotFields("UNIQUE ID"). _
CurrentPage = strPage
' **Do a Bunch of Stuff**
End If
Next
rngSelection.Clear ' Optional - if the range really needs to be cleared
MsgBox "All Reports have been created.", vbInformation + vbOKOnly
You need to understand the changes and ask any further questions that you might have. Below are the changes made to the original code.
Introduced calculation of last cell in Column A having some data
Introduced For Loop instead of using labels eliminating the need of deleting rows