I want to get the result from the cell in excel so that if F8 = .01 to .6 then it will show E8&A and if F8 = .7 to .125 then it will show E8&B. If not anything then it will show E8. I have wirtten that statement
(=IF(AND(F8>=0.01,F8<=0.06),E8&"A"),IF(AND(F8>=0.07,F8<=0.125),E8&"B",E8)
but it show #VALUE , what is the problem? Please help me
VALUE does not show after input the statement from your suggestion that
=IF(AND(F8>=0.01,F8<=0.06),E8&"A",IF(AND(F8>=0.07,F8<=0.125),E8&"B",E8))
but a problem newly create that
when I press .05 in F8 it shows E8&A but when I press .06 it shows only E8 and next when I press .07 it shows E8&B
my question is why it shows only E8 when I press .06 in F8
Thank you
It's because of the parentheses () used incorrectly.
=IF(AND(F8>=0.01, F8<=0.06),E8 & "A", IF(AND(F8>=0.07, F8<=0.125), E8 & "B", E8))
will work
Try:
=IF(AND(F8>=0.01,F8<=0.06),E8&"A",IF(AND(F8>=0.07,F8<=0.125),E8&"B",E8))
ie move the ) after "A" to the end.
Here you go. This implementation specifies something to do when values are outside of your ranges.
=IF(F8>=0.01,IF(F8>0.06,IF(F8>0.125,"Greater than 0.125",E8&"B"),E8&"A"),"less than 0.01")
You'll have to edit the formula based on what you want to happen to values between 0.06 and 0.07 (this is not specified in your question).
What does E8&"A" means? Try + instead of &...
=IF(AND(F8>=0.01,F8<=0.06),E8+"A"),IF(AND(F8>=0.07,F8<=0.125),E8+"B",E8)
Related
So for school i'm working with this huge excel Dataset. I'm trying Excel 365 to find the word terrorist and return the value 1 with the follow code:
=IF'(A22="terrorist", "No", "Yes")
But I keep getting the excel error.
There is a problem with the function
you type =1+1, cell shows: 2
to get around this type an apostrophe (') first:
you type '=1+1 cell shows =1+1
Whats going wrong?
Remove the ' - use simply:
=IF(A22="terrorist", 1, 0)
This will show 1 if A22 = "terrorist", otherwise it will show 0.
Sat down for a small project that's supposed to count combat details for my tabletop gaming sessions during lunch, turns out the excel code hates me.
C8 = CREATURE MAX HP
D8 = CREATURE CURRENT HP
E8 = CREATURE DAMAGE HEALED
F8:L8 = PC1:PC8 DAMAGE CAUSED
My formula for adding these together is contained in cell D8 and looks like this:
=C8-SUM(F8:L8)+E8
But I don't want my cell to add higher than what's contained in C8. How can I keep that from happening?
Does min work for you? =MIN(C8-SUM(F8:L8)+E8, C8) – Alexis Olson 8 mins ago
I'll go ahead an make this into an answer.
You can approach this in a couple of ways. The first is using MIN which takes the lesser of the two arguments.
=MIN(C8-SUM(F8:L8)+E8, C8)
You could also use an IF(test, result if true, result if false) function.
=IF(C8-SUM(F8:L8)+E8 > C8, C8, C8-SUM(F8:L8)+E8)
or equivalently, pulling the C8 value out, you have
=C8 + IF(E8 > SUM(F8:L8), 0, E8 - SUM(F8:L8))
trying to get an excel spreadsheet to do what I need and im basically computer illiterate. Any help would be appreciated
Basically what I need is the below statements combined
If E8 = Officer and G8 = Active Duty then 1
If E8 = Officer and G8 = Active Reserve then 2
if E8 = Enlisted and G8 = Active Duty then 3
If E8 = Enlisted and G8 = Active Reserve then 4
Ive been able to figure out some basic and, if statements but this one with multiple outcomes is throwing me for a loop, Also it all needs to go into one cell if possible. Thanks guys
=MATCH(E8&G8,{"OfficerActive Duty","OfficerActive Reserve","EnlistedActive Duty","EnlistedActive Reserve"},0)
OR
=(MATCH(E8,{"Officer","Enlisted"},0)-1)*2+MATCH(G8,{"Active Duty","Active Reserve"},0)
This is what you need:
IF(AND(E8="Officer",G8="Active Duty"), 1,
IF(AND(E8="Officer",G8="Active Reserve"), 2,
IF(AND(E8="Enlisted",G8="Active Duty"), 3, 4)))
If you need to use this quite a lot in the future, better to set up as a table to look up and here is how you can do it with an array formula (click Ctrl + Shift + Enter together):
=INDEX($C$2:$C$5,MATCH(E2&F2,$A$2:$A$5&$B$2:$B$5,0),1)
This way, you can dynamically update your criteria any time you want.
Plus, you can set up a drop down list from your criteria like this (Data > Data Tools > Data Validation):
I think this should be a fairly quick question, hopefully!
I would like to add a line to the following formula, after the line that says IF C6 =0,0 that if B6 is equal to W, the result should be 9.95:
=IF(C6=0,0,
MAX(SUM(IF(F6<=0,0,39),
IF(F6>30,(C6*0.08),
IF(F6>20,(C6*0.07),
IF(F6>10,(C6*0.06),
IF(F6>5,(C6*0.05),
IF(F6>2,(C6*0.04),
IF(F6>1,(C6*0.03),
IF(F6>=0.25,(C6*0.02),
IF(F6>=0,(0.03*C6*F6),0))))))))),43))
Basically, the first thing it should look for is that if C6 is 0, the result should be 0 - but if C6 > 0, then to check B6 for the letter 'W', and if that is true, then to display 9.95, otherwise to go along with the remainder of the formula.
Try this:-
=IF(C6=0,0,
IF(B6="W",9.95,
MAX(SUM(IF(F6<=0,0,39),
IF(F6>30,(C6*0.08),
IF(F6>20,(C6*0.07),
IF(F6>10,(C6*0.06),
IF(F6>5,(C6*0.05),
IF(F6>2,(C6*0.04),
IF(F6>1,(C6*0.03),
IF(F6>=0.25,(C6*0.02),
IF(F6>=0,(0.03*C6*F6),0))))))))),43)))
I have a problem in excel, I want to make mathematical equation, ive tried it and I have problem with that function, it gives me error. I want have result in G6 if i type W in F6, then it will type in G6 : E6 if i type L in F6, then it will type in G6 : -D6 i think that I can get -D6 by multiplying D6 with -1
by the way : KDYŽ means IF in my language
Try this (you need to nest your IFs) (I also incorporated #ScottHunter answer on string literals):
In English:
=If(F6="L", D6*-1, If(F6="W", E6, ""))
In your language:
=KDYŽ(F6="L"; D6*-1; KDYŽ(F6="W"; E6; ""))
The above works for me as shown here:
You need quotes around your string literals (i.e. F6="L").