Use ADODB to INSERT INTO specific table in an Excel workbook - excel

Question

I'm trying to use ADODB to execute a SQL INSERT INTO command into an Excel worksheet. I was able to insert into the worksheet when there was only one column in the worksheet using this code:
Const adOpenStatic = 3
Const adLockOptimistic = 3
Const adCmdText = &H1
Dim Connection As ADODB.Connection
Set Connection = New ADODB.Connection
Connection.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data
Source=PathToFile.xls;Extended
Properties=Excel 8.0;"
Connection.Open
Dim SQL As String
SQL = "INSERT INTO [Sheet1$] VALUES('Test')"
Call Connection.Execute(SQL, , CommandTypeEnum.adCmdText Or ExecuteOptionEnum.adExecuteNoRecords)
But I want to have three separate tables in the same worksheet and specify which of the tables to insert into. How can I do this? I tried creating the tables, naming them, and using this SQL statement to specify a table but I kept getting the error: The Microsoft Jet database engine could not find the object 'TestTable1'. Make sure the object exists and that you spell its name and the path name correctly.
SQL = "INSERT INTO TestTable1(ID) VALUES('test')"

Answer 1

You can do something like this:
Sub TestInsert()
InsertRecords Sheet4.Range("B3").CurrentRegion, _
"insert into # values('AAA','BBB','CCC')"
InsertRecords Sheet4.Range("F3").CurrentRegion, _
"insert into # values('ZZZ')"
InsertRecords Sheet4.Range("H3").CurrentRegion, _
"insert into # values('Whirled',99999)"
End Sub
Sub InsertRecords(rng As Range, sSQL As String)
Const S_TEMP_TABLENAME As String = "SQLtempTable"
Dim oConn As New ADODB.Connection
Dim sPath
'name the selected range
On Error Resume Next
ThisWorkbook.Names.Item(S_TEMP_TABLENAME).Delete
If Err.Number <> 0 Then Err.Clear
On Error GoTo haveError
ThisWorkbook.Names.Add Name:=S_TEMP_TABLENAME, RefersToLocal:=rng
sPath = ThisWorkbook.Path & "\" & ThisWorkbook.Name
oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source=" & sPath & _
";Extended Properties=""Excel 8.0;HDR=Yes"""
oConn.Execute Replace(sSQL, "#", S_TEMP_TABLENAME)
Exit Sub
haveError:
MsgBox Err.Description
End Sub
Before:
After: