Prevent close during BeforeSave event - excel

Question

Question:
A user attempts to close a file they've made changes to. A prompt comes up asking if they would like to save and they click 'Yes'. If there is code in the BeforeSave event that cancels the save, is there a way to also cancel the closing?
Background:
We make frequent use of "blank files", pre-formatted files with formulas and such that a user can open, enter data, and save under a new file name. It's that last step that caused problems. Users would save their data to the blank file, which meant we'd have to restore it to its original condition (clear out data, re-enter formulas that were deleted/overwritten, revert changes to formatting, etc.).
To prevent this, I added the following code to all blank files:
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
If instr(UCase$(ThisWorkbook.Name), "BLANK") <> 0 then
If SaveAsUI = False Then
MsgBox "This is the blank file. You can't save it. " _
& "Please choose 'Save As' and save with a new file name.", _
vbExclamation, "Can't Save Blank"
Cancel = True
End If
End If
End Sub
If the user tries to save data to a blank file, they'll get a message telling them they can't, and to use the Save As dialog instead. And if I need to make changes to the blank file, I can use the Save As dialog to save it using the same file name.
The problem lies when I make changes to a blank file and try to close that file. The prompt will come up asking me if I want to save my changes. Not thinking about it, I'll click 'Yes'. Then my code will be triggered preventing a save and notifying me, as intended. But when I click 'OK' on my message, the file immediately closes without saving changes.
What I'd like is some way to prevent the file from closing when saving has been canceled.

Answer 1

I took the code from there and modified it.
save as dialog excel code
I hope it solves your problem or at least it will after some small changes.
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Dim varResult As Variant
Dim ActBook As Workbook
'displays the save file dialog
varResult = Application.GetSaveAsFilename(FileFilter:= _
"Excel Files (*.xlsx), *.xlsx", Title:="Save As", _
InitialFileName:=Application.ActiveWorkbook.Path)
'checks to make sure the user hasn't canceled the dialog
If varResult <> False Then
ActiveWorkbook.SaveCopyAs Filename:=varResult '_
'FileFormat:=xlWorkbookNormal
Exit Sub
End If
End Sub
' No it is just in case the user doesn't want to save the file and cancels the first dialog
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
If InStr(UCase$(ThisWorkbook.Name), "BLANK") <> 0 Then
If SaveAsUI = False Then
MsgBox "This is the blank file. You can't save it. " _
& "Please choose 'Save As' and save with a new file name.", _
vbExclamation, "Can't Save Blank"
Cancel = True
End If
End If
End Sub
Edit:
After pressing closing button:
Everytime changes have been made a window to 'save as' pops up and after saving a copy it just closes, no more poping up windows afterwards
If no changes have been made it just closes the workbook
the code:
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Dim varResult As Variant
Dim ActBook As Workbook
If InStr(UCase$(ThisWorkbook.Name), "BLANK") <> 0 Then
If Not ThisWorkbook.Saved Then
'displays the save file dialog
varResult = Application.GetSaveAsFilename(FileFilter:= _
"Excel Files (*.xlsm), *.xlsm", Title:="Save As", _
InitialFileName:=Application.ActiveWorkbook.Path)
'checks to make sure the user hasn't canceled the dialog
If varResult <> False Then
ActiveWorkbook.SaveCopyAs Filename:=varResult '_
'FileFormat:=xlWorkbookNormal
ThisWorkbook.Saved = True
Exit Sub
Else
ThisWorkbook.Saved = True
End If
End If
End If
End Sub
' Just in case the user presses save in options
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
If InStr(UCase$(ThisWorkbook.Name), "BLANK") <> 0 Then
If SaveAsUI = False Then
MsgBox "This is the blank file. You can't save it. " _
& "Please choose 'Save As' and save with a new file name.", _
vbExclamation, "Can't Save Blank"
Cancel = True
End If
End If
End Sub
Final version
After pressing closing button:
Everytime changes have been made a window asking if you want to save changes appears (one can cancel it, say no or yes)
If yes was chosen (default button) a 'save as' window pops up and after saving a copy it just closes, no more poping up windows afterwards
If no changes have been made it just closes the workbook
The code:
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Dim varResult As Variant
Dim ActBook As Workbook
Dim MsgBoxAnswer As Variant
If InStr(UCase$(ThisWorkbook.Name), "BLANK") <> 0 Then
If Not ThisWorkbook.Saved Then
MsgBoxAnswer = MsgBox("Do you want to save changes?", vbYesNoCancel + vbExclamation + vbDefaultButton1, "Microsoft Office Excel")
If MsgBoxAnswer = vbYes Then
MsgBox "This is the blank file. Save it with a new file name.", _
vbExclamation, "Can't Save Blank"
'displays the save file dialog
varResult = Application.GetSaveAsFilename(FileFilter:= _
"Excel Files (*.xlsm), *.xlsm", Title:="Save As", _
InitialFileName:=Application.ActiveWorkbook.Path)
'checks to make sure the user hasn't canceled the dialog
If varResult <> False Then
ActiveWorkbook.SaveCopyAs Filename:=varResult '_
'FileFormat:=xlWorkbookNormal
ThisWorkbook.Saved = True
Exit Sub
Else
ThisWorkbook.Saved = True
End If
ElseIf MsgBoxAnswer = vbNo Then
ThisWorkbook.Saved = True
ElseIf MsgBoxAnswer = vbCancel Then
Cancel = True
End If
End If
End If
End Sub
' Just in case the user presses save in options
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
If InStr(UCase$(ThisWorkbook.Name), "BLANK") <> 0 Then
If SaveAsUI = False Then
MsgBox "This is the blank file. You can't save it. " _
& "Please choose 'Save As' and save with a new file name.", _
vbExclamation, "Can't Save Blank"
Cancel = True
End If
End If
End Sub