Replacing NewLine Character with an Empty String - excel

Question

I want to add a new column with blank fields in my existing CSV data.
My current code is like this:
Dim data As IEnumerable(Of String) =
File.ReadLines(filename,Encoding.GetEncoding("iso-8859-1")).
Select(Function(line, index)
If index = 0 Then
Return "new_column," & line
Else
Return "," & line
End If
End Function)
File.WriteAllLines(savePath, data)
The problem is that "new_column" is being added on the line breaks. So, what I did is to open the CSV file in Excel and used the following steps:
Ctrl + H to open up the Find and Replace dialog box.
On the Find What text box, I used Ctrl + J to enter a line break character. I followed the instructions here
I tried using ReadAllText but the rows are not in the correct order after writing it.
Is there an alternate same way to what I am doing with Excel in VB.NET?

Answer 1

With a CSV file saved from Excel, if there is a line break in a cell then the cell value will be surrounded with double-quotes and the line break is represented by a Chr(10).
For example,
saved as a CSV file and opened in a hex editor gives (note: 10 decimal = 0A hexadecimal)
43 6F 6C 20 41 2C 43 6F 6C 20 42 2C 22 4C 69 6E Col A,Col B,"Lin
65 0A 62 72 65 61 6B 22 2C 43 6F 6C 20 44 0D 0A e·break",Col D··
So you need something which will regard a line break inside a double-quoted string as not being a new line.
The TextFieldParser can be configured to do that by setting the .HasFieldsEnclosedInQuotes property to True.
For example, with the above data,
Option Infer On
Option Strict On
Imports System.IO
Imports System.Text.RegularExpressions
Imports Microsoft.VisualBasic.FileIO
Module Module1
Sub Main()
Dim src = "C:\temp\Book1.csv"
Dim dest = "C:\temp\newColumn.csv"
Using tfp As New TextFieldParser(src)
tfp.HasFieldsEnclosedInQuotes = True
tfp.Delimiters = {","}
Dim re As New Regex("[,\n]")
Using sw As New StreamWriter(dest, False, Text.Encoding.GetEncoding("iso-8859-1"))
While Not tfp.EndOfData
Dim thisLine = tfp.ReadFields()
sw.WriteLine("new_column," & String.Join(",", thisLine.Select(Function(p) If(re.IsMatch(p), Chr(34) & p & Chr(34), p))))
End While
End Using
End Using
End Sub
End Module
generates
6E 65 77 5F 63 6F 6C 75 6D 6E 2C 43 6F 6C 20 41 new_column,Col A
2C 43 6F 6C 20 42 2C 22 4C 69 6E 65 0A 62 72 65 ,Col B,"Line·bre
61 6B 22 2C 43 6F 6C 20 44 0D 0A ak",Col D··
Which can be opened in Excel to give:
You may need to make it more robust than putting double-quotes around only entries with a Chr(10), for example entries with a comma in need the delimiters too.
I wrote it to also delimit fields with commas, although that isn't shown in the example data.
Of course, once you have the individual entries from a line in the array thisLine, you could replace the Chr(10) with a space, if desired.