Range.Address Truncated when Used in Formula (String Too Long) - excel

Question

I have code that loops through the 5th column of a user-selected range, and if the current cell in the 5th column matches a criteria, adds the next 10 cells in the same row to a range. At the end of everything, it sums the final range in cell A1 if it is empty.
Sub SumItems()
Dim selectedRange As Range
Set selectedRange = Selection
Dim sumRange As Range
Dim i As Long
For i = 1 To selectedRange.Rows.Count
If selectedRange(i, 5) = "Yes" Then
If sumRange Is Nothing Then
Set sumRange = Range(selectedRange(i, 5).Offset(0, 1), selectedRange(i, 5).Offset(0, 10))
Else
Set sumRange = Union(sumRange, Range(selectedRange(i, 5).Offset(0, 1), selectedRange(i, 5).Offset(0, 10)))
End If
End If
Next i
If Not sumRange Is Nothing Then
If IsEmpty(Range("A1")) Then
Range("A1").Formula = "=SUM(" + sumRange.Address(False, False) + ")"
Else
MsgBox "Cannot paste in cell A1, it is not empty."
Exit Sub
End If
Else
MsgBox "No matching rows were found."
Exit Sub
End If
End Sub
The sheets I am running this on are long. So sumRange will usually be a union of a lot of different areas in the sheet. I've noticed that once sumRange.Areas.Count exceeds 18, I have problems with the Range("A1").Formula statement. The sumRange.Address(False, False) string gets cut off after the 18th area. I believe this is because the .Address string length is too long and it just coincides with 18 areas with this sheet.
I developed a temporary solution but it limits the number of areas the subroutine can handle and is clunky and verbose. I set up temporary range variables to split sumRange into if it has more than 18 areas and the IF statement now reads something like:
If Not sumRange Is Nothing Then
If IsEmpty(Range("A1")) Then
If sumRange.Areas.Count > 18 Then
Dim k As Long
Dim tmpSumRange1 As Range
Dim tmpSumRange2 As Range
Dim tmpSumRange3 As Range
' And so on...
For k = 1 To sumRange.Areas.Count
If k <= 18 Then
If tmpSumRange1 Is Nothing Then
Set tmpSumRange1 = sumRange.Areas(k)
Else
Set tmpSumRange1 = Union(tmpSumRange1, sumRange.Areas(k))
End If
ElseIf k > 18 And k <= 36 Then
If tmpSumRange2 Is Nothing Then
Set tmpSumRange2 = sumRange.Areas(k)
Else
Set tmpSumRange2 = Union(tmpSumRange2, sumRange.Areas(k))
End If
ElseIf k > 36 And k <= 54 Then
If tmpSumRange3 Is Nothing Then
Set tmpSumRange3 = sumRange.Areas(k)
Else
Set tmpSumRange3 = Union(tmpSumRange3, sumRange.Areas(k))
End If
ElseIf
' And so on until I get to k = 180...
End If
Next k
If Not tmpSumRange1 Is Nothing And tmpSumRange2 Is Nothing And tmpSumRange3 Is Nothing Then
Range("A1").Formula = "=SUM(" + tmpSumRange1.Address(False, False) + ")"
ElseIf Not tmpSumRange1 Is Nothing And Not tmpSumRange2 Is Nothing And tmpSumRange3 Is Nothing Then
Range("A1").Formula = "=SUM(" + tmpSumRange1.Address(False, False) + "," + tmpSumRange2.Address(False, False) + ")"
ElseIf Not tmpSumRange1 Is Nothing And tmpSumRange2 Is Nothing And Not tmpSumRange3 Is Nothing Then
Range("A1").Formula = "=SUM(" + tmpSumRange1.Address(False, False) + "," + tmpSumRange2.Address(False, False) + "," + tmpSumRange3.Address(False, False) + ")"
ElseIf
' And so on all the way up to tmpSumRange10...
End If
Else
Range("A1").Formula = "=SUM(" + sumRange.Address(False, False) + ")"
End If
Else
MsgBox "Cannot paste in cell A1, it is not empty."
Exit Sub
End If
Else
MsgBox "No matching rows were found."
Exit Sub
End If
I know there has to be a better solution than this. I haven't found anything in my searching. Nor have I found anyone that has experienced the same problem. I need the A1 cell to have the SUM formula with the ranges in it otherwise I would just sum the values in the subroutine and insert the value instead of the formula.

Answer 1

So there are two separate but probably related issues:
Range.Address truncates at a maximum of 255 characters, without error. This is odd, because while Excel is smart enough to not leave you with a partial address string that would raise a 1004, at the same time it's stupid enough to allow an Address to truncate, which obviously will yield unexpected results if used in formula, etc.
There's a kinda-sorta 255 character limit for string arguments to Excel functions if the string is passed ByVal (see this old thread) for discussion, but I've excerpted relevant bits, below) .
Excel function parameters will accept a reference to a string with length of up to 32767 (32k or 2^15 total possible lengths). ... But what if we pass a value instead of a reference?
we can pass a reference to a string up to 32k, we can only pass a string value up to 255
It seemed like the problem was a result of Formula length, but that was a red herring.
You're definitely encountering the truncation issue with Range.Address.
Problem: Range.Address truncates at 255 Characters
Because this happens silently, any formula you build based on truncated address is going to be adversely affected; the results won't be what you're expecting because the formula will not represent all parts of the range!
I've logged this as a bug with Microsoft in case you want to follow the issue:
https://github.com/MicrosoftDocs/VBA-Docs/issues/49
In the meantime, fortunately the solution is remarkably simple (although it was not simple to arrive at!), see if you can adapt to your purposes, but the idea is:
Create a System.Collections.ArrayList into which we store all of the individual Area addresses (alternatively you could use a Variant but those are somewhat clunkier what with the ReDim etc.)
Cast that ArrayList to a variant array using the ToArray() method
Use the result of the Join function in your Formula string
Sub example()
Dim myNames As Object
Dim formula as String
Dim k As Long
Dim sumRange As Range
Dim thisArea As Range
' Example:
' -- creates a range consisting of 100 Areas
' -- this .Address will truncate to 252 characters!
For k = 1 To 200 Step 2
Set thisArea = Range("A" & k)
If sumRange Is Nothing Then Set sumRange = thisArea
Set sumRange = Union(sumRange, thisArea)
Next
' Iterate the sumRange union and add each Area to an ArrayList
Set myNames = CreateObject("System.Collections.ArrayList")
For Each thisArea In sumRange.Areas
myNames.Add thisArea.Address
Next
' Output to worksheet:
Dim outputCell As Range
Set outputCell = Range("F1")
formula = "=Sum(" & Join(myNames.ToArray(), ",") & ")"
outputCell.Formula = formula
End Sub
And you can see the extraordinarily long formula (Len == 650) in the worksheet:
If you're not comfortable working with an ArrayList, you could brute force it as a `String:
' Iterate the sumRange union and add each Area to our formula string
formula = "=Sum("
For Each thisArea In sumRange.Areas
formula = formula & thisArea.Address & ","
Next
formula = Left(formula, Len(formula) - 1)
formula = formula & ")"