How to turn multiple find and replaces into more efficient loop - excel

Question

Below is what I have in the middle of a bigger macro I've made. Creating loops and especially inserting them into larger macros successfully is something I don't know how to do. Any help is appreciated
F column has a header. How far the rows could be occupied is dynamic. When I made this I selected the entire column instead of offset 1 cell down control shift down to select simply because the input was small enough it didn't matter. Now the inputs are bigger and are slowing everything down.
' remove FIRST style tags from description *Add new ones here*
Sheets("Columns").Select
Columns("F:F").Select
Selection.Replace What:="<span style*>", Replacement:="", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
'2
Sheets("Columns").Select
Columns("F:F").Select
Selection.Replace What:="<div style=*>", Replacement:="", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
'3
Sheets("Columns").Select
Columns("F:F").Select
Selection.Replace What:="<p style*>", Replacement:="<p>", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
...
'18
Sheets("Columns").Select
Columns("F:F").Select
Selection.Replace What:="<tbody>", Replacement:="", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
Below is new code
Sub Sample()
Dim StartTime As Double
Dim SecondsElapsed As Double
'Remember time when macro starts
StartTime = Timer
Dim Ar(1 To 17) As String '~~> 4 to number of items
Dim i As Long
Dim Ar2(1) As String '~~> 1 to number of items
Dim a As Long
Ar(1) = "<span style*>"
Ar(2) = "<div>"
Ar(3) = "<div style=*>"
Ar(4) = "<tbody>"
Ar(5) = "</div>"
Ar(6) = "<ul style=*>"
Ar(7) = "<li style=*>"
Ar(8) = "<table style*>"
Ar(9) = "<col style*>"
Ar(10) = "<tr style=*>"
Ar(11) = "<td class=*>"
Ar(12) = "<colgroup>"
Ar(13) = "</colgroup>"
Ar(14) = "</tbody>"
Ar(15) = "</td>"
Ar(16) = "</tr>"
Ar(17) = "</table>"
For i = 1 To UBound(Ar)
Sheets("Columns").Columns(6).Replace What:=Ar(i), _
Replacement:="", _
LookAt:=xlPart, _
SearchOrder:=xlByRows, _
MatchCase:=False, _
SearchFormat:=False, _
ReplaceFormat:=False
Next i
Ar2(1) = "<p style*>"
For a = 1 To UBound(Ar2)
Sheets("Columns").Columns(6).Replace What:=Ar2(a), _
Replacement:="<p>", _
LookAt:=xlPart, _
SearchOrder:=xlByRows, _
MatchCase:=False, _
SearchFormat:=False, _
ReplaceFormat:=False
Next a
'Determine how many seconds code took to run
SecondsElapsed = Round(Timer - StartTime, 2)
'Notify user in seconds
MsgBox "This code ran successfully in " & SecondsElapsed & " seconds", vbInformation
End Sub

Answer 1

Store all the search items in an array and then replace them in a loop. For example (UNTESTED)
Sub Sample()
Dim Ar(1 To 4) As String '~~> 4 to number of items
Dim i As Long
Ar(1) = "<span style*>"
Ar(2) = "<p style*>"
Ar(3) = "<div style=*>"
Ar(4) = "<tbody>"
For i = 1 To Ubound(Ar)
Sheets("Columns").Columns(6).Replace What:=Ar(i), _
Replacement:="", _
LookAt:=xlPart, _
SearchOrder:=xlByRows, _
MatchCase:=False, _
SearchFormat:=False, _
ReplaceFormat:=False
Next i
End Sub