I want to find a value in a row, that is, I want find "3" (which is in D4) in column B, when this value(3) has been found in B"X", D5 has to be the value of B"X+1", D6 has to be equal to B"X+2" and so on. Preferably, the solution has to be as formulas and not VBA.
Thanks by your help
Use:
=INDEX(B:B,MATCH($D$4,B:B,0)+ROW(1:1))
Put that in D5 and copy down.
Related
[
Hi - I am trying to find duplicates in column A, if there is a duplicate in column A check column B is the same and if not return a field in column C.
Example in image - A2 to A4 are the same and so is B2 to B4 therefore no action required. A5 to A8 are the same but B5 to B8 are different so they need to be checked.
I believe the correct formula is a combination of IF and COUNTIFS but I can’t quite get it right. I can find the duplicates easily in column A or B but can’t get the co-dependency right I think I am missing something in the middle
=IF(COUNTIFS(A:A,A2, B:B, B2)>1), “no action”, “check”)
you have 2 open brackets and 3 close brackets in the formula . Otherwise its working for me.
I have number from 1 to 100 in column A1 to A100.
I am trying to achieve two results from data.
I want separately 1,2,3,4,5,6,7,8,9 and another one 10,20,30,40,50,60,70,80,90,100
Please help me
Maybe, in B1:
=1*(LEN(A1)=1)+2*(RIGHT(A1)="0")
double-click the fill handle and sort A:B on ColumnB.
This question is a bit vague. If you are looking to count by 10s, try adding a 10 in cell B1 and then adding the formula =B1+10 in cell B2. You can drag that formula down to count by 10s.
Let's say we want in column B "0, 1,2,3,4,5,6,7,8,9" and in column C "0, 10,20,30,40,50,60,70,80,90,100", put:
- =MOD(A1,10) as formula for the cell B1
- =INT(A1/10)*10 as formula for the cell C1
and then copy them to rest of the rows.
Hi need some help of Excel guru please. Excel sample
Formula would do something like this:
if Last enty in column A is last enty then show B of the same row
So basicaly the E1 should be empty, but if I add text for B5 then E1 should display what is in B5.
And if I add new device in A6 then it should read B6 and so on.
To find last cell I use =INDEX(Sheet1!A:A,INDEX(MAX((Sheet1!A:A<>"")*(ROW(Sheet1!A:A))),0)).
Thanks for your help.
How about:
=INDEX(B:B,COUNTA(A:A))
Figured out my self when I put all on paper
=LOOKUP(2,1/(Sheet1!A:A<>""),Sheet1!B:B)
Or you may try this...
=INDEX(B:B,MATCH("zzz",A:A))
http://oi60.tinypic.com/30mvcli.jpg
So basically I want to check all values in column B against all values in column A. If there is a match I want column C to write the value of column in the corresponding row that A is on (as shown in the picture).
Not sure which forumla(s) I need to use to do this. Thanks.
Todd, I think a simple if statement should work here.
=IF(A1=B1,A1,"")
The above formula will copy the data from A1 into C1 only if A1 is equal to B1.
Enter this formula into C1 and drag it down for as many rows as you need (Excel will change the 1s to 2s etc). Let me know if this works for you :)
=IF(ISNUMBER(MATCH(A1, B:B, 0)), A1, "")
Put this to C1. Drag down for as many rows as you need.
In C1 try,
=if(countif(b:b, a1), a1, "")
Fill down as necessary.
I'm trying to write a simple formula to check whether either 1 or both cells are blank and, if so, leave the resulting cell blank. I want the resulting cell to only display a calculation if both cells are filled in.
I've got this do far though it doesn't work as I wanted: =IF(OR(C4<>"",B4<>""),A4-C4,"")
b4 has a date and c4 has a numeric value (4). the formulate is in d4. I want to check if b4 or c4 are blank and, if so, leave d4 blank too, else take c4 from a4 (14 as of now).
It should work:
=IF(ISBLANK(C4);"";IF(ISBLANK(D4);"";A4-C4))
It checks if C4 is a blank cell, if not then checks if D4 is blank, if not then does the math.
I recommend using ISBLANK to check for blank cells.
Formula for your D4:
=IF(OR(ISBLANK(B4), ISBLANK(C4)),,A4-C4)
Just try this formula
=IF(AND(C4<>"",B4<>""),A4-C4,"")
Also, I used =IF(A2&B2="",TRUE VALUE, FALSE VALUE) which worked great