Updating closed Access database with Excel VBA - excel

Question

I have a macro in Excel to delete tables in Access.
Is there is a way to do this without opening the Access database?
Set AppAcc = Nothing
Set AppAcc = New Access.Application
AppAcc.Visible = True
AppAcc.OpenCurrentDatabase "C:\MyStuff\MyDataBase.mdb"
AppAcc.DoCmd.SetWarnings False
With AppAcc
.DoCmd.OpenQuery "Delete_Query1"
.DoCmd.OpenQuery "Delete_Query2"
.DoCmd.OpenQuery "Delete_Query3"
End With
AppAcc.DoCmd.SetWarnings True
AppAcc.Quit acQuitSaveNone
Set AppAcc = Nothing

Answer 1

Absolutely, there is a way. Since MS Access is a database it can connect via a backend like all major RDBMS's (Oracle, SQL Server, Postgres, etc.). Below demonstrates ODBC/OLEDB connections using ADO. Then, further below is an alternative version with DAO which you are currently running but can do so without Access.Application and DoCmd calls.
Both should even work without having MS Access GUI (the MS Office app) installed. Each use late binding. For early binding, add VBA references Microsoft ActiveX Data Objects #.# Library or Microsoft DAO #.# Object Library, then modify Dim and Set statements.
ADO
Dim conn As Object
Set conn = CreateObject("ADODB.Connection")
' WITH ODBC DRIVER
conn.Open "DRIVER=Microsoft Access Driver (*.mdb, *.accdb);DBQ=C:\MyStuff\MyDataBase.mdb;"
' WITH ODBC DSN
'conn.Open "DSN=MS Access Database;DBQ=C:\MyStuff\MyDataBase.mdb;"
' WITH OLEDB PROVIDER
'conn.Open "PROVIDER=Microsoft.ACE.OLEDB.12.0;Data Source=C:\MyStuff\MyDataBase.mdb;"
' THREE WAYS TO CALL ACTION QUERIES
conn.Execute "{CALL Delete_Query1}"
conn.Execute "EXEC Delete_Query2"
conn.Execute "Delete_Query3"
Set conn = Nothing
DAO
Dim conn As Object, db As Object
Set conn = CreateObject("DAO.DBEngine.120")
Set db = conn.OpenDatabase("C:\MyStuff\MyDataBase.mdb")
db.Execute "Delete_Query1"
db.Execute "Delete_Query2"
db.Execute "Delete_Query3"
Set db = Nothing
Set conn = Nothing