VBA automation error: -2147221080 (800401a8) - excel

Question

I have a problem with my code whereby everything works fine except one line that keeps getting the automation error even though the sheet exists. My code is supposed to delete sheets based on a certain name column and despite editing it, the error still occurs. Would appreciate if someone could help me out here, thanks!
Sub DeleteSelectedSheets()
Const lngNameCol = 8 ' names in column (H)
' lngRow = 5 ' data start in row 5
Dim i As Long
Dim lastrow As Long
Dim row_num As Long
Dim wsh_to_delete As Worksheet
Dim main_sheet As Worksheet
Dim ws As Worksheet
Set main_sheet = ActiveSheet
lastrow = main_sheet.Range("A" & main_sheet.Rows.Count).End(xlUp).Row
Application.ScreenUpdating = False
For Each ws In ActiveWorkbook.Worksheets
For row_num = 5 To lastrow
If Not ws Is Nothing Then
If ws.Name = main_sheet.Cells(row_num, lngNameCol).Value Then
On Error Resume Next
Application.DisplayAlerts = False
Worksheets(ws.Name).Delete
Application.DisplayAlerts = True
On Error GoTo 0
End If
End If
Next
Next
End Sub
The automation error occurs here:
If ws.Name = main_sheet.Cells(row_num, lngNameCol).Value Then
Although the code deleted the sheets, the error keeps popping out after every row

Answer 1

I think the problem lies in the deletion of the worksheet during the loop.
Try your loops the other way around, cycling through each sheet to see if it is the name you're looking for:
For row_num = 5 To lastrow
For Each ws In ActiveWorkbook.Worksheets
If Not ws Is Nothing Then
If ws.Name = main_sheet.Cells(row_num, lngNameCol).Value Then
On Error Resume Next
Application.DisplayAlerts = False
Worksheets(ws.Name).Delete
Application.DisplayAlerts = True
On Error GoTo 0
End If
End If
Next
Next

Answer 2

When you delete element from a collection, the whole collection is a bit "unhappy". With the worksheets, the best way is to loop from the total count of the worksheets to 1 and check whether your worksheet should be deleted:
Sub TestMe()
Dim i As Long
For i = Worksheets.Count To 1 Step -1
If Worksheets(i).Name = "Something" And Worksheets.Count > 1 Then
Application.DisplayAlerts = False
Worksheets(i).Delete
Application.DisplayAlerts = True
End If
Next
End Sub
Additionally, there is a rule for Worksheets.Count>1, because the last worksheet of the workbook cannot be deleted.