Excel: Find Which Range A Value Belongs To If Any (Sparse Ranges) - excel

Question

I know one can use LOOKUP or VLOOKUP to find range from a list of contiguous ranges a value belongs to. I know you can do some functional but awful things with IF statements to do similar things.
What I'm looking to do:
I have a calculated value between 1 and 100% (represents how far along a lunar synodic orbital cycle the moon is).
I need to essentially identify if the calculated value falls in:
0 - 0.6 Full
11.9 - 13.1 3/4 Waning
24.4 - 25.6 1/2 Waning
36.9 - 38.1 1/4 Waning
49.4 - 50.6 No Moon
61.9 - 63.1 1/4 Waxing
74.4 - 75.6 1/2 Waxing
86.9 - 88.1 3/4 Waxing
99.4 - 100 Full
So I need to check if the calculated value falls within any of the calculated ranges and if so, return the associated text. If it does not, it would be desirable to return a blank ("").
I'm wondering if I have to just use a really ugly nested IF statement or if there is some graceful way to use one or two lookup functions to accomplish what I want. The fact the overall range one is testing against is sparse (parts of the range should return a blank) is the challenge.
One approach I can see is not using a sparse range - just filling in between each of the existing ranges a range that returns blank, then using a LOOKUP or VLOOKUP. Is that my best option or is there a better solution?
For example:
0 - 0.6 Full
0.7 - 11.8 <blank>
11.9 - 13.1 3/4 Waning
13.2 - 24.3 <blank>
24.4 - 25.6 1/2 Waning
25.7 - 36.8 <blank>
36.9 - 38.1 1/4 Waning
38.2 - 49.3 <blank>
49.4 - 50.6 No Moon
50.7 - 61.8 <blank>
61.9 - 63.1 1/4 Waxing
63.2 - 74.3 <blank>
74.4 - 75.6 1/2 Waxing
75.7 - 86.8 <blank>
86.9 - 88.1 3/4 Waxing
88.2 - 99.3 <blank>
99.4 - 100 Full

Answer 1

Given your original data, split into three columns and formatted as a table named PhaseTbl, with column headers Min, Max and Phase, I believe the following will do what you require, with the value to be tested in A2:
=IFERROR(INDEX(PhaseTbl,AGGREGATE(15,6,1/((A2>=PhaseTbl[Min])*(A2<=PhaseTbl[Max]))*ROW(PhaseTbl)-ROW(PhaseTbl[#Headers]),1),3),"")
Phase Table
Sample Results
You can examine how this formula works by using the formula evaluation tool.
In brief, working from the inside --> out
(A2>=PhaseTbl[Min])*(A2<=PhaseTbl[Max])
We take our value and, by multiplying the Boolean comparisons, we return an array of 1's and 0's depending on whether we satisfy the condition that in the same row the tested value is both greater than (or equal to) the Minimum and less than or equal to the maximum.
1/{1,0,0,...}
Converts the 0's into error values.
The array form of the AGGREGATE function, with the ignore errors argument, will then return the row number of the match. We adjust that for the table location to return the value from column 3 within the INDEX function.

Answer 2

As well as Ron's answer, you can use an array formula:
=IFERROR(INDEX(PhaseTbl[State],MATCH(1,([#Value]>=PhaseTbl[Min])*([#Value]<=PhaseTbl[Max]),0)),"")

Answer 3

I have another option with three basic formulas IF, COUNTIFS and INDEX(MATCH()) and no arrays. As other answers have suggested, I'd firstly recommend you split your data into 3 columns: Min, Max and Phase, so it looks like the following example.
Input Data:
A B C
1|Min |Max | Phase |
+---+-----+-----------+
| 0 |0.6 | Full |
|11.9|13.1|3/4 Waning |
|24.4|25.6|1/2 Waning |
|36.9|38.1|1/4 Waning |
|49.4|50.6| No Moon |
|61.9|63.1|1/4 Waxing |
|74.4|63.1|1/2 Waxing |
|86.9|88.1|3/4 Waxing |
|99.4|100 | Full |
With the above data starting in A1, your output data starting in F1 would look like the below example, with the below formula in G2.
Formula:
=IF(COUNTIFS(A:A,"<="&F2,B:B,">="&F2)=1,INDEX(C:C,MATCH(F2,A:A,1)),"")
Output Data:
F G
1|Value|Result |
+-----+----------+
| 0 |Full |
|0.6 |Full |
|0.7 | |
|11.8 | |
|11.9 |3/4 Waning|
|13.1 |3/4 Waning|
|13.2 | |
|24.3 | |
|24.4 |1/2 Waning|
|25.6 |1/2 Waning|
|25.7 | |
|99.3 | |
|99.4 |Full |
|100 |Full |
|110 | |
Formula Explained:
=IF(COUNTIFS(A:A,"<="&F2,B:B,">="&F2)=1,INDEX(C:C,MATCH(F2,A:A,1)),"")
Count if any of the values in the "Min" list are less than or equal to F2 AND any of the values in the "Max" list are greater than or equal to F2
If the count returns 1, return the "Phase" on the same row as the "Min" value that is less than F2 (this is done in the MATCH part of the INDEX(MATCH()) formula, with the match type set to "1: Less than")
If the count does not return 1, return a blank cell.